|цена открытия - цена закрытия|* 1000 * 0,1 (минимальный лот) + предыдущий лот от убыточной позиции

//+------------------------------------------------------------------+
//|                                                   Beton_Exp5.mq4 |
//|                                                              Oxy |
//|                                   http://oxy.opentraders.ru/bio/ |
//+------------------------------------------------------------------+
#property copyright "Oxy"
#property link      "http://oxy.opentraders.ru/bio/"
#property version   "1.00"
#property strict
//------- Внешние параметры советника -----------------------------------------+
extern double LotBegin            = 0.1;       // Первоначальный лот
extern int    SellOrBuy           = 1;         // SELL=1, BUY=0
extern int    TakeProfit          = 100;       // Take Profit
              
extern int    Slippage   = 30;         // Проскальзывание цены
extern int    MagicNumber= 567582;     // Идентификатор ордера
//------- Глобальные переменные советника -------------------------------------+
string Symb;
int    Ticket=-1;
int    Umn;
double StepLot;
double MinLot;
double MaxLot;
double NewLot=LotBegin;
datetime timePrev    = -1;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   if (!IsTradeAllowed()) { Print("Необходимо разрешить советнику торговать"); return(INIT_FAILED);}  
   if (TakeProfit<MarketInfo(Symbol(), MODE_STOPLEVEL)) { Print("Неправильно выставлен Take Profit!");   return(INIT_FAILED);}
   if (LotBegin<MarketInfo(Symbol(), MODE_MINLOT)) { Print("Неправильно выставлен первоначальный лот!"); return(INIT_FAILED);}
   Symb = Symbol();
   Umn=1;
   if(Digits>3) Umn = 1000;
   if(Digits==3)Umn = 100;
   if(Digits==2)Umn = 10;
   StepLot = MarketInfo(Symbol(), MODE_LOTSTEP);
   MinLot  = MarketInfo(Symbol(), MODE_MINLOT);
   MaxLot  = MarketInfo(Symbol(), MODE_MAXLOT);
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason) {  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
    // на новой свече
    if(timePrev != Time[1] && HavePos ()) {
      if (OrderSelect(Ticket, SELECT_BY_TICKET, MODE_TRADES)) {
        int    ot        = OrderType();
        double lotSize   = OrderLots();
        // ---закрываем----------       
        if(ot==0){
          if (!OrderClose(OrderTicket(), OrderLots(), Bid, Slippage))  { Print("Не удалось закрыть ордер!"); return;}
        }
        if(ot==1) {
          if (!OrderClose(OrderTicket(), OrderLots(), Ask, Slippage))  { Print("Не удалось закрыть ордер!"); return;}
        }
        // ---рассчитываем лот---
        if(OrderSelect(Ticket,SELECT_BY_TICKET,MODE_HISTORY)) {
          double orPr = OrderProfit();
          if(orPr<0) {            
            double someLot    = lotSize + orPr*-1*MinLot;
            NewLot = MathRound(someLot/StepLot)*StepLot;
            if (NewLot>MaxLot) NewLot=MaxLot;
          }
        }
      }
    }    
    // открываем новую позицию
    if(timePrev != Time[1] && HavePos () == false) {
      timePrev = Time[1];
      if(SellOrBuy==0) {   
        BuyPos(NewLot);
        NewLot=LotBegin;
      }
      if(SellOrBuy==1) {
        SellPos(NewLot);
        NewLot=LotBegin;
      }
    }
  }
//+------------------------------------------------------------------+
bool HavePos () {
  int i, k = OrdersTotal ();
  for (i=k-1; i>=0; i--) {
    if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==Symb && OrderMagicNumber()==MagicNumber) {
        if(OrderType()==0 || OrderType()==1) Ticket = OrderTicket();
        return (true);
      }
    }
  }
  return (false);
}
//+------------------------------------------------------------------+
void BuyPos(double _lot) {
  double sl=0;
  double tp = Ask + TakeProfit*Point; 
  Ticket = OrderSend(Symb, OP_BUY, _lot, NormalizeDouble(Ask,Digits), Slippage, NormalizeDouble(sl,Digits), NormalizeDouble(tp,Digits), NULL, MagicNumber); 
}
void SellPos(double _lot) {
  double sl=0;
  double tp = Bid - TakeProfit*Point; 
  Ticket = OrderSend(Symb, OP_SELL, _lot, NormalizeDouble(Bid,Digits), Slippage, NormalizeDouble(sl,Digits), NormalizeDouble(tp,Digits), NULL, MagicNumber); 
}
//+------------------------------------------------------------------+