seronn

 
Уровень 4
Добро пожаловать в мой блог!


Группа "Стол заказов MQL"

Рейтинг 2146


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от seronn



Прошу сделать полуавтоматический советник Комментариев 4
2016-08-18 09:16:46Рейтинг 0

Прошу сделать советник по стрелкам индикатора

Добрый день!
Прошу сделать советника по интересному индикатору(наблюдаю за ним — вроде бы не перерисовывает, входы неплохие):
— предусмотреть SL и TP для ордера
— вход по индикатору, выход по SL, TP или по противоположному сигналу
Индикатор:
FractalZigZagNoRepaint.mq 4 (0 Kb)
Спасибо!)

// не понял как сюда нормально загрузить файл, ссылка на внешний обменник:
my-files.ru/jh5rkz
  • 0
  • Просмотров: 4924
  • 29 февраля 2016, 11:17
  • seronn
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Исправить ошибки в индикаторе
28 февраля 2016
01 марта 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (5)

+
0
Готово:




//+------------------------------------------------------------------+
//|                                                    FractalZZ.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 2000;     // язь
extern int TrailingStop  = 0;        // трал
extern int Slip          = 30;       // реквот
extern int Shift         = 2;        // сдвиг
extern int Magic         = 123;      // магик

extern string IndName="FractalZigZagNoRepaint";
extern string s="    ------ FractalZigZagNoRepaint -----";
extern bool CalculateOnBarClose    = true;
extern int  ZZDepth                = 12;
extern int  ZZDev                  = 5;

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double white = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,0,Shift);
   double red   = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,1,Shift);

   if(white<100)
     {
      PutOrder(0,Ask);
     }

   if(red<100)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos()
  {
   double white = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,0,Shift);
   double red   = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,1,Shift);
//---
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(red<100)
                 {
                  if(!OrderClose(OrderTicket(),OrderLots(),Bid,Slip,Red))
                     Print("OrderClose error ",GetLastError());
                 }
              }
            if(OrderType()==OP_SELL)
              {
               if(white<100)
                 {
                  if(!OrderClose(OrderTicket(),OrderLots(),Ask,Slip,Blue))
                     Print("OrderClose error ",GetLastError());
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderProfit()<0)
        {
         lot=OrderLots()*KLot;
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=0; i<OrdersTotal(); i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() || OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double white = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,0,Shift);
   double red   = iCustom(NULL,0,IndName,CalculateOnBarClose,ZZDepth,ZZDev,1,Shift);

   if(CountTrades()<1)
     {
      OpenPos();
     }
   else ClosePos();

   if(TrailingStop>0) Trailing();

   Comment("\n White: ",white,
           "\n Red: ",red);
  }
//+------------------------------------------------------------------+
avatar

  35  AM2 Сообщений: 16250 - Андрей

  • 29 февраля 2016, 14:54
+
0
Очень оперативно! Спасибо) А возможно его подправить чтобы сделки открывались при принципу «одна стрелочка-одна сделка», т.е. если появляется подряд 2 белые, открывать 2 buy подряд и т.д.?
avatar

  4  seronn Автор Сообщений: 26

  • 29 февраля 2016, 15:24
+
0
Поправил: www.opentraders.ru/downloads/1077/




Редактирован: 29 февраля 2016, 20:40
avatar

  35  AM2 Сообщений: 16250 - Андрей

  • 29 февраля 2016, 16:37
+
0
Спасибо! Всё работает. Жаль неожиданно не впечатляющие результаты по тестам советника пока...((( Видимо что-то ещё нужно додумывать(
avatar

  4  seronn Автор Сообщений: 26

  • 29 февраля 2016, 19:13
+
0
А можно добавить закрытие по профиту в валюте. И ещё бы добавить разрешение на торговлю отдельно в бай и сел и магики отдельно в бай и сел. Хочу закрывать отдельно бай и сел по профиту.
avatar

  15  cashyra Сообщений: 392 - Юра

  • 17 марта 2016, 12:34

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий