переделать под пятизнак / Стол заказов MQL / OpenTraders - блогплатформа для трейдеров финансовых рынков

0

Переделывать не возьмусь, по ТЗ напишу в следующем месяце.

35 AM2 Сообщений: 16285 - Андрей

24 мая 2016, 13:47
↓

0

Вот сырой набросок:


//+------------------------------------------------------------------+
//|                                                     Tyanulka.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+

#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 500;      // лось
extern int TakeProfit    = 500;      // язь
extern int Delta         = 300;      // расстояние для отложки
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 1;        // 1-подтягивание ордера по МА
extern int BuySell       = 0;        // 1-buylimit 2-selllimit 0-off
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,0,0,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Mode()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderStopLoss()==0 || OrderTakeProfit()==0)
              {
               if(OrderType()==0) m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-StopLoss*Point,OrderOpenPrice()+TakeProfit*Point,0,Blue);
               if(OrderType()==1) m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+StopLoss*Point,OrderOpenPrice()-TakeProfit*Point,0,Blue);
              }
           }
        }
     }
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   double ma = iMA(NULL,0,12,0,0,0,0);
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUYLIMIT)
              {
               if(Bid-ma>Delta*Point)
                 {
                  if(OrderOpenPrice()!=NormalizeDouble(ma,Digits))
                    {
                     mod=OrderModify(OrderTicket(),NormalizeDouble(ma,Digits),OrderStopLoss(),OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELLLIMIT)
              {
               if(ma-Bid>Delta*Point)
                 {
                  if(OrderOpenPrice()!=NormalizeDouble(ma,Digits))
                    {
                     mod=OrderModify(OrderTicket(),NormalizeDouble(ma,Digits),OrderStopLoss(),OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() || OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   Mode();
   if(BULevel>0) BU();
   if(TrailingStop>0) Trailing();
   if(CountTrades()<1 && BuySell==1 && CountOrders(2)<1) PutOrder(2,Ask-Delta*Point);
   if(CountTrades()<1 && BuySell==2 && CountOrders(3)<1) PutOrder(3,Ask+Delta*Point);
  }
//+------------------------------------------------------------------+

35 AM2 Сообщений: 16285 - Андрей

25 мая 2016, 10:50
↓

0

а можно оставить код который я выложил и просто добавить в него БУ и уровень БУ все оставить как есть, просто добавить БУ?

10 cardon Автор Сообщений: 376

25 мая 2016, 23:05
↓

0

а можно оставить код который я выложил и просто добавить в него БУ и уровень БУ все оставить как есть, просто добавить БУ?

Это будет слишком просто!

Перенес в свой код тянулку, чтобы можно было в тестере погонять.

www.opentraders.ru/downloads/1186/

35 AM2 Сообщений: 16285 - Андрей

26 мая 2016, 07:14
↓

0

хорошо что вы не выполнили мою первую в топике просьбу) я вам не тот код скинул, тот старый
вот сюда надо то что я просил, просто БУ))))

cloud.mail.ru/public/FAiP/qPY82pnBx

10 cardon Автор Сообщений: 376

26 мая 2016, 08:37
↓

0

Смотрите тот вариант который я сделал и в базу скинул, там все работает. И чем отличается старый от нового?

35 AM2 Сообщений: 16285 - Андрей

26 мая 2016, 08:47
↑
↓

0

он проще в настройке, тралит и лимитные и стоп ордера, он прост в настройке, в том я не понимаю 1/3 настроек типа «0-Cloce,1-Open,2-High-v,3-Low-n,4-Median»,
в этом все понятно, откройте его на графике, там все улучшено в настройках, выпадающие меню.
я ваш вариант смотрел, по простоте настройки второй код лучше во многом.

10 cardon Автор Сообщений: 376

26 мая 2016, 09:34
↑
↓

0

Нет я уже сделал 2 варианта, тем более мне это не оплачивается.

35 AM2 Сообщений: 16285 - Андрей

26 мая 2016, 10:57
↓

0

просто БУ и все, я не просил писать новый, а просто добавить пару строчек

простите за наглость.

10 cardon Автор Сообщений: 376

26 мая 2016, 11:35
↓

0

нет так нет

10 cardon Автор Сообщений: 376

26 мая 2016, 11:46
↓

0

просто БУ и все, я не просил писать новый, а просто добавить пару строчек
простите за наглость.

С чужим кодом намучаешься только.

35 AM2 Сообщений: 16285 - Андрей

26 мая 2016, 22:46
↓

+1

Просто добавил БУ. Может так оно и лучше


//+-----------------------------------------------------------------------------------------------+
//|                                                                             e_Тянулка_102.mq4 |
//|                                                                                               |
//|                                                                                               |
//|                                                                                               |
//| http://www.tradingsystems.pips.ru                                             LUKA.  25.03.15 |
//+-----------------------------------------------------------------------------------------------+
#property copyright   "LUKA."
#property link        "http://www.tradingsystems.pips.ru"
#property version     "1.00"
#property description "Обновлено 25.03.15" 
#property description "" 
#property description "Тянет ордер по МА" 
//#property strict 

//+-----------------------------------------------------------------------------------------------+
/**/
//+-----------------------------------------------------------------------------------------------+
string _Par____________________1="- Параметры Ордера -";
input  ENUM_TIMEFRAMES    TimeFrame     = PERIOD_H1;     // Таймфрейм МА
input  int                Distance      = 3;             // Дистанция от МА
input  int                StopLoss      = 50;            // 0 - неиспользуем
input  int                TakeProfit    = 150;           // 0 - неиспользуем
input  int                Magic         = -1;            // Магик ордера, (-1) - любой

//+-----------------------------------------------------------------------------------------------+
extern string _Par____________________2 = "- Параметры МА в BUY -";
extern int                PeriodBuy     = 34;            //  Период МА в Buy
extern ENUM_MA_METHOD     MethodBuy     = MODE_SMMA;     //
extern ENUM_APPLIED_PRICE PriceBuy      = PRICE_HIGH;    //      

//+-----------------------------------------------------------------------------------------------+
extern string _Par____________________3 = "- Параметры МА в SELL -";
input  int                PeriodSell    = 34;            //  Период МА в Sell
extern ENUM_MA_METHOD     MethodSell    = MODE_SMMA;     //
extern ENUM_APPLIED_PRICE PriceSell     = PRICE_LOW;     //      

//+-----------------------------------------------------------------------------------------------+
string _Par____________________4 = "- Параметры исполнения -";
bool               UseSound      = True;          // Использовать звуковой сигнал
string             NameFileSound = "expert.wav";  // Звук успеха
string             SoundError    = "timeout.wav"; // Звук ошибки
int                NumberOfTry   = 3;             // Количество торговых попыток

//+-----------------------------------------------------------------------------------------------+
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ

//+-----------------------------------------------------------------------------------------------+
#include <stdlib.mqh>

//+-----------------------------------------------------------------------------------------------+
int    nor;
double poi,dig;
//+-----------------------------------------------------------------------------------------------+
//|                                                                                               |>
//+-----------------------------------------------------------------------------------------------+
int OnInit()
  {
//---
   poi=MarketInfo(OrderSymbol(), MODE_POINT);
   dig=(int)MarketInfo(OrderSymbol(), MODE_DIGITS);

   if(dig==3 || dig==5) nor=10; else nor=1;
//---
   return (INIT_SUCCEEDED);
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                                                               |>
//+-----------------------------------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---  
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                                                               |>
//+-----------------------------------------------------------------------------------------------+
void OnTick()
  {
//---
   double sl_s=0,tp_s=0,sl_b=0,tp_b=0,s1,s2,n1,n2;

   s1=iMA(_Symbol, TimeFrame, PeriodBuy,  0, MethodBuy,  PriceBuy,  0);
   s2=iMA(_Symbol, TimeFrame, PeriodSell, 0, MethodSell, PriceSell, 0);

   if(poi==0) if(StringFind(OrderSymbol(),"JPY")<0) poi=0.0001; else poi=0.01;

   n1=ND(s1+Distance*poi*nor, "");
   n2=ND(s2-Distance*poi*nor, "");

   if(StopLoss!=0) sl_b=n1-StopLoss  *poi*nor; else sl_b=0;
   if(TakeProfit!=0) tp_b=n1+TakeProfit*poi*nor; else tp_b=0;
   if(StopLoss!=0) sl_s=n2+StopLoss  *poi*nor; else sl_s=0;
   if(TakeProfit!=0) tp_s=n2-TakeProfit*poi*nor; else tp_s=0;

   if(BULevel>0) BU();

   for(int i=0; i<OrdersTotal(); i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(Magic<0 || OrderMagicNumber()==Magic)
           {
            if(OrderSymbol()==_Symbol)
              {
               if(OrderType()== OP_BUYLIMIT) ModifyOrder(n1, sl_b, tp_b, clrWhite);
               if(OrderType()== OP_SELLSTOP) ModifyOrder(n1, sl_s, tp_s, clrWhite);
               if(OrderType()==OP_SELLLIMIT) ModifyOrder(n2, sl_s, tp_s, clrWhite);
               if(OrderType()==  OP_BUYSTOP) ModifyOrder(n2, sl_b, tp_b, clrWhite);
              }
           }
        }
     }
  }
//+-----------------------------------------------------------------------------------------------+
//|  Модификация одного предварительно выбранного ордера.                                         |>
//+-----------------------------------------------------------------------------------------------+
void ModifyOrder(double pp=-1,double sl=0,double tp=0,color cl=CLR_NONE)
  {
//---
   bool   fm;
   int    er,it;
   double op,os,ot;

   if(pp<=0) pp=OrderOpenPrice();
   if(sl<0 ) sl=OrderStopLoss();
   if(tp<0 ) tp=OrderTakeProfit();

   pp=NormalizeDouble(pp, dig);
   sl=NormalizeDouble(sl, dig);
   tp=NormalizeDouble(tp, dig);
   op=NormalizeDouble(OrderOpenPrice() , dig);
   os=NormalizeDouble(OrderStopLoss()  , dig);
   ot=NormalizeDouble(OrderTakeProfit(), dig);

   if(pp!=op || sl!=os || tp!=ot)
     {
      for(it=1; it<=NumberOfTry; it++)
        {
         if(!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
         while(!IsTradeAllowed()) Sleep(5000);
         RefreshRates();
         fm=OrderModify(OrderTicket(),pp,sl,tp,0,cl);
         if(fm)
           {
            if(UseSound) PlaySound(NameFileSound); break;
           }
         else
           {
            er=GetLastError();
            if(UseSound) PlaySound(SoundError);
            Print("Ошибка ModifyOrder # ");
            Print("Error(",er,") modifying order: ",ErrorDescription(er),", try ",it);
            Sleep(1000*10);
           }
        }
     }
  }
//+-----------------------------------------------------------------------------------------------+
//|  Нормализует число в зависимости от количества цифр после запятой.                            |>
//+-----------------------------------------------------------------------------------------------+
double ND(double d,string name="")
  {
//---
   if(name=="") name=_Symbol;
//---
   return (NormalizeDouble(d, (int)MarketInfo(name, MODE_DIGITS)));
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+-----------------------------------------------------------------------------------------------+

35 AM2 Сообщений: 16285 - Андрей

27 мая 2016, 08:46
↓

0

спасибо большое

\0/

10 cardon Автор Сообщений: 376

27 мая 2016, 09:44
↓

Предыдущая запись в группе Выставление отложенных ордеров на свечках закрытым на 1/3	Следующая запись в группе Заказ: Объединить индикаторы.
22 мая 2016	25 мая 2016

Группа "Стол заказов MQL"

Свыше 4000 заказов уже выполнено бесплатно!

РЕКОМЕНДУЮ

Лучшее от cardon

переделать под пятизнак

Комментарии (13)

Рейтинг брокеров FOREX

Из недавнего:

	cardon Уровень 10

Авторизация

Группа "Стол заказов MQL"

Свыше 4000 заказов уже выполнено бесплатно!

РЕКОМЕНДУЮ

Лучшее от cardon

переделать под пятизнак

Вставка изображения

СМАЙЛИКИ

Позитив

Негатив

Роли

Еще

Плакаты, знаки

Комментарии (13)

Рейтинг брокеров FOREX

Из недавнего: