reemavera
Забанен

 
Уровень 4
Забанен. Причина: клон


Группа "Стол заказов MQL"

Рейтинг 2151


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Советник на одном индикаторе.

Уважаемый Андрей!
Напишите пожалуйста советник на индикаторе = 100pipsfxgainer4

Вход в сделку — смена цвета индикатора.
Тейкпрофит

Пожалуйста напишите так – чтобы после взятия тейка – советник в сделку бы не заходил а заходил только на смене цвета индикатора.!!!

Стоплосс
Трал
Безубыток
Время работы
Анализируемый бар
И вывести в настройки советника — все настройки индикатора

100pipsfxgainer4.mq4 (5 Kb)
  • 0
  • Просмотров: 4984
  • 10 июля 2016, 17:52
  • reemavera
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Напешите советника по индикатору стохастика.
Следующая запись в группе  
МА со сдвигом
09 июля 2016
13 июля 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (20)

+
0
Индикатор не дышит

avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 10 июля 2016, 18:30
+
0
индикатор не работает или чего то не хватает?
avatar

  14  Thunder61 Сообщений: 166 - Thunder61

  • 10 июля 2016, 18:54
+
0
Индикатор загрузил в следующем заказе. Здесь не получается.
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 10 июля 2016, 19:05
+
0
Напишите точнее сигнал на бай и селл. Индикатор скачал, лишний топик удалил.
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 10 июля 2016, 19:16
  • ↑
+
0
Синий цвет индикатора — это покупка /BAY/
Белый цвет индикатора — это продажа /SELL/
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 10 июля 2016, 19:21
+
0
Мне очень нужно — чтобы после взятия тейка – советник в сделку бы не заходил а заходил только на смене цвета индикатора.!!!
Синий цвет индикатора — это покупка /BAY/
Белый цвет индикатора — это продажа /SELL/
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 10 июля 2016, 19:26
+
0
Так нормально?



//+------------------------------------------------------------------+
//|                                                     FXGainer.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 0;        // трал
extern int TrailingStep  = 20;       // шаг трала
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик
extern string IndName    = "100pipsfxgainer4";

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2009                                                     |
//|  Описание : Возвращает флаг разрешения торговли по времени.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    hb - часы времени начала торговли                                       |
//|    mb - минуты времени начала торговли                                     |
//|    he - часы времени окончания торговли                                    |
//|    me - минуты времени окончания торговли                                  |
//+----------------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double blue  = iCustom(NULL,0,IndName,0,Shift);
   double white = iCustom(NULL,0,IndName,2,Shift);
   double blue2=iCustom(NULL,0,IndName,0,Shift+1);
   double white2=iCustom(NULL,0,IndName,2,Shift+1);

   if(blue<1000 && white2<1000)
     {
      PutOrder(0,Ask);
     }

   if(white<1000 && blue2<1000)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderType()==OP_BUY)
           {
            if(Bid-OrderOpenPrice()>TrailingStop*Point)
              {
               if(OrderStopLoss()<Bid-(TrailingStop+TrailingStep-1)*Point)
                 {
                  mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }

         if(OrderType()==OP_SELL)
           {
            if((OrderOpenPrice()-Ask)>TrailingStop*Point)
              {
               if(OrderStopLoss()>Ask+(TrailingStop+TrailingStep-1)*Point || OrderStopLoss()==0)
                 {
                  mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double blue  = iCustom(NULL,0,IndName,0,Shift);
   double white = iCustom(NULL,0,IndName,2,Shift);
   double blue2=iCustom(NULL,0,IndName,0,Shift+1);
   double white2=iCustom(NULL,0,IndName,2,Shift+1);

   if(CountTrades()<1 && isTradeTimeInt(StartHour,StartMin,EndHour,EndMin))
     {
      if(t!=Time[0])
         OpenPos();
      t=Time[0];
     }

   if(BULevel>0) BU();
   if(TrailingStop>0) Trailing();

   Comment("\n blue: ",blue,
           "\n white: ",white,
           "\n blue2: ",blue2,
           "\n white2: ",white2);
  }
//+------------------------------------------------------------------+

Редактирован: 10 июля 2016, 19:53
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 10 июля 2016, 19:49
+
0
Ай-Ай!
А как быть с настройками индикатора в параметрах советника?
Или я настраиваю параметры индикатора — как мне нужно — и советник в таком виде его будет применять? Я правильно понимаю?
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 10 июля 2016, 20:30
+
0
Завтра утром посмотрю настройки.
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 10 июля 2016, 21:07
  • ↑
+
0
Посмотрел :)  www.opentraders.ru/downloads/1249/
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 11 июля 2016, 07:56
+
0
Робот работает, не перезходит после тейка, но в сделки заходит через раз. Иногда заходит в поизцию и не переворачивается, хотя по инди катору должен быть переворот.
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 11 июля 2016, 11:51
+
0
avatar

  4  reemavera Автор Сообщений: 30 - Забанен

  • 11 июля 2016, 11:55
+
0
Иногда заходит в поизцию и не переворачивается, хотя по инди катору должен быть переворот.

Какой переворот? Где он прописан в ТЗ?
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 11 июля 2016, 13:22
+
0
Все сигналы отработаны. Просьбы делать скрины крупнее точек 1200х500.

avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 11 июля 2016, 13:32
+
0
Решил и я потестировать на демо.
Открывает неплохо, но тупо держит ордера.
Индикатор 10 поменялся, а он не закрывает или не переворачивается.
avatar

  7  gek63 Сообщений: 101

  • 13 июля 2016, 12:04
  • ↑
+
0
Открывает неплохо, но тупо держит ордера.
Индикатор 10 поменялся, а он не закрывает или не переворачивается.

В ТЗ нет переворотов и обратного закрытия, а автор топика не просил добавить ни то ни другое.
Редактирован: 13 июля 2016, 12:08
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 13 июля 2016, 12:08
  • ↑
+
0
Не могли бы добавить переворот?:) 
avatar

  7  gek63 Сообщений: 101

  • 13 июля 2016, 16:35
  • ↑
+
0
Это топик автора, он здесь хозяин :) 
avatar

  35  AM2 Сообщений: 16388 - Андрей

  • 13 июля 2016, 16:41
  • ↑
+
0
Вы пробовали, сколько тейк и стоп ставили?
avatar

  7  gek63 Сообщений: 101

  • 13 июля 2016, 17:26
  • ↑
+
0
По моему беда индикатора в том, что он ставит палочку после закрытия свечи.
avatar

  7  gek63 Сообщений: 101

  • 14 июля 2016, 21:11

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий