lorik
Лариса

 
Уровень 19

  Торгую в компаниях:


Группа "Стол заказов MQL"

Рейтинг 2073



РЕКОМЕНДУЮ



Советник на пробой Н4

Пробойный советник Н4

Прошу сделать пробойный советник на Н4.
Условия работы:
— работает на Н4;
— коробка начало, конец недели, мах недели, min недели;
— выставка отложенных ордеров на мах недели, min недели
Задаваемые параметры:
— лот;
— СЛ и ТП;
— расстояние выставки ордеров от мах и min;
— трал;
— проскальзывание;
— магик.
Спасибо!
  • +3
  • Просмотров: 2468
  • 8 сентября 2016, 18:14
  • lorik
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Поправить советник
Следующая запись в группе  
Скрыть stop loss
07 сентября 2016
11 сентября 2016

Комментарии (8)

+
0
Завтра буду смотреть.
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 8 сентября 2016, 18:16
+
0
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 8 сентября 2016, 20:29
+
0
Спасибо!
avatar

  19  lorik Автор Сообщений: 357 - Лариса

  • 9 сентября 2016, 06:58
+
0
Вы меня не правильно поняли *cry* , аналогично стратегии дневной пробой, только для Н4, за прошлую неделю выставляются отложенные ордера макс мин.недели.
avatar

  19  lorik Автор Сообщений: 357 - Лариса

  • 9 сентября 2016, 07:25
+
0
Поясните на скринах как можно подробнее, с пояснениями на картинке чтобы не было никаких разночтений.
Редактирован: 9 сентября 2016, 09:09
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 9 сентября 2016, 08:50
+
0
Вы меня не правильно поняли  , аналогично стратегии дневной пробой, только для Н4, за прошлую неделю выставляются отложенные ордера макс мин.недели.


Кстати в первоначальном ТЗ нет ни слова о прошлой неделе.

— коробка начало, конец недели, мах недели, min недели;
— выставка отложенных ордеров на мах недели, min недели
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 9 сентября 2016, 09:57
+
0
Для прошлой недели коробок <img src='http://opentraders.ru/templates/skin/g6h/images/smilies/002.gif' alt=' :) '>&nbsp; 



//+------------------------------------------------------------------+
//|                                                      Korobok.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 50;       // лось
extern int TakeProfit    = 70;       // язь
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 0;        // трал
extern int TrailingStep  = 20;       // шаг трала
extern int Expiration    = 10;       // истечение ордера в часах
extern int Delta         = 100;      // дельта
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,TimeCurrent()+Expiration*3600,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutRect(string name,datetime t1,double p1,datetime t2,double p2,color clr)
  {
   ObjectDelete(0,name);
//--- создадим прямоугольник по заданным координатам
   ObjectCreate(0,name,OBJ_RECTANGLE,0,t1,p1,t2,p2);
//--- установим цвет прямоугольника
   ObjectSetInteger(0,name,OBJPROP_COLOR,clr);
  }
//+------------------------------------------------------------------+
//| Ступенчатый трал               if(TrailingStop>0) Trailing();    |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*Point)
                 {
                  if(OrderStopLoss()<Bid-(TrailingStop+TrailingStep-1)*Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*Point)
                 {
                  if(OrderStopLoss()>Ask+(TrailingStop+TrailingStep-1)*Point || OrderStopLoss()==0)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
   double h = iHigh(NULL,PERIOD_W1,1);
   double l = iLow(NULL,PERIOD_W1,1);

   if(BULevel>0) BU();
   if(TrailingStop>0) Trailing();

   PutRect("Rect",iTime(NULL,PERIOD_W1,0),l,iTime(NULL,PERIOD_W1,1),h,Blue);

   if(CountTrades()<1)
     {
      if(CountOrders(4)<1 && Bid<h) PutOrder(4,h+Delta*Point);
      if(CountOrders(5)<1 && Bid>l) PutOrder(5,l-Delta*Point);
     }
  }
//+------------------------------------------------------------------+

Редактирован: 9 сентября 2016, 11:22
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 9 сентября 2016, 11:21
+
0
Вот, то что заказывала. Спасибо!
avatar

  19  lorik Автор Сообщений: 357 - Лариса

  • 9 сентября 2016, 18:57

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари