Забыл добавить для 4-х знака

Уважаемый Андрей переделайте заказ zakaz.opentraders.ru/30345.html

Какой именно вариант править? Из там несколько. Скиньте ссылку на файлик в базе?

www.opentraders.ru/downloads/889/ последний

Там где с какой свечи вход с фильтром макди и обязательно для 4-х знака разница большая между 5-ти и 4-х

Составьте ТЗ по образцу: am2.opentraders.ru/29048.html
А то ниче не пойму  

Написать советник на основе двух индикаторов BBands_Stop_v1 и MACD_MOD.где индикатор MACD_MOD включаемый и отключаемый являеться фильтром сделок обязательно для 4-х знака в советнике присутcтвуют:
1 Время торговли откл/вкл
2 Тейк/стоп
3 Сделка на сигнал пока не закрылась сделка не открываеться
4 В сове должны быть 2 параметра регулироваемых с индикатора BBands_Stop_v1
а Параметр Length
б Параметр Money Risk
5 В сове должна быть регулировка с на какой свече входить на открытой или закрытой при сигнале индикатора BBands_Stop_v1
6 Условие входа при включеном фильтре на скрине сигнал на сел

7 сигнал на бай с точностью наоброт
8 Ввести сову параметр который отвечал бы за величину штриха в индикаторе MACD_MOD то есть какой я параметр устанавливаю в сове с того и разрешаем торговать парметр показан на следущем скрине

Есть все 10 п.   www.opentraders.ru/downloads/1344/

Андрей спасибо огромное прошу прощение как обычно забыл один пункт добавьте пожалусто
11 Увеличение лота после минуса с переключением или любая сделка или контр сделка тобишь если получили минус на селе то увеличиваем баевую ну и наоборот если возможно 

Андрей сова молчит вот настройки

вот журнал

вот скрин сделки несостоявшейся

Андрей сова молчит вот настройки

Молчит значит не совпали все условия. Поиграйте с настройками.

Поиграю но на скрине видно что условие входа в сделку все были

Да перепутал скрины с мт4 япопробую вечером без фильтра вначале

Я в коде тоже ошибку нашел, исправил, сейчас на тесте стоит.

Вот исправленный вариант который сейчас у меня на тесте стоит:

//+------------------------------------------------------------------+
//|                                                       Modnik.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property description "BBands expert advisor"

//--- Inputs
extern double Lots         = 0.1;   // лот
extern double KLot         = 2;     // умножение лота
extern double MaxLot       = 5;     // максимальный лот
extern double MACDLevel    = 0.001; // максимальный лот
extern int    StopLoss     = 5000;  // лось
extern int    TakeProfit   = 5000;  // язь
extern int    StartHour    = 0;     // час начала торговли
extern int    StartMin     = 30;    // минута начала торговли
extern int    EndHour      = 23;    // час окончания торговли
extern int    EndMin       = 30;    // минута окончания торговли
extern int    Shift        = 1;     // сдвиг
extern int    Slip         = 30;    // слипаж
extern bool   MACD         = true;  // MACD включен
extern int    Magic        = 123;   // магик
//----
extern string IndName1     = "BBands_Stop_v1";
extern int    Length       = 20;   // период BB 
extern int    Deviation    = 2;    // отклонение ВВ
extern double MoneyRisk    = 1;    // Offset Factor

extern string IndName2     = "MACD_MOD";
input int     InpFastEMA   = 12;   // Fast EMA Period
input int     InpSlowEMA   = 26;   // Slow EMA Period
input int     InpSignalSMA = 9;    // Signal SMA Period

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)   sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)   sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderProfit()<0)
        {
         lot=OrderLots()*KLot;
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2009                                                     |
//|  Описание : Возвращает флаг разрешения торговли по времени.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    hb - часы времени начала торговли                                       |
//|    mb - минуты времени начала торговли                                     |
//|    he - часы времени окончания торговли                                    |
//|    me - минуты времени окончания торговли                                  |
//+----------------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
//--- get Ind
   double BBBlue  = iCustom(NULL,0,IndName1,Length,Deviation,0,Shift);
   double BBRed   = iCustom(NULL,0,IndName1,Length,Deviation,1,Shift);
   double BBBlue2 = iCustom(NULL,0,IndName1,Length,Deviation,0,Shift+1);
   double BBRed2  = iCustom(NULL,0,IndName1,Length,Deviation,1,Shift+1);

   double blue = iCustom(NULL,0,IndName2,InpFastEMA,InpSlowEMA,InpSignalSMA,1,Shift);
   double red  = iCustom(NULL,0,IndName2,InpFastEMA,InpSlowEMA,InpSignalSMA,0,Shift);

   bool buy,sell;
   
   if(MACD)
     {
      buy  = BBBlue>0 && BBRed2>0  && red<1000  && red>MACDLevel;
      sell = BBRed>0  && BBBlue2>0 && blue<1000 && blue<-MACDLevel;
     }
     
   if(!MACD)
     {
      buy  = BBBlue>0 && BBRed2>0;
      sell = BBRed>0  && BBBlue2>0;
     }
          
   if(sell)
     {
      PutOrder(1,Bid);
     }

   if(buy)
     {
      PutOrder(0,Ask);
     }
//---
  }
//+------------------------------------------------------------------+
//| OnTick function                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1 && isTradeTimeInt(StartHour,StartMin,EndHour,EndMin)) OpenPos();
  }
//+------------------------------------------------------------------+

По сигналу открыл:

Есть и покупки:

Андрей спасибо огромное попробую

Андрей я не знаю где вы смотрите но на скрине -0.00010 посмотрите где обведен желтым если убрать — то получаеться 0.00010 штрих с этим значением больше чем 0.0004 
Редактирован: 5 октября 2016, 15:45

В 8 позиции написано какой параметр в водим от него и торуем соответственно если ставим 0.0004 то и — 0.0004 на скрине -0.00010 сова промолчала а с минимальным параметром 0.0001 торговала

Андрей прошу прощение с нулями запутался все нормально работает большое спасибо