River

 
Уровень 9
Добро пожаловать в мой блог!


Группа "Стол заказов MQL"

Рейтинг 2146


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от River



Прошу написать советник Комментариев 2
2016-05-18 15:28:01Рейтинг 0

Советник на индикаторе FL23 Комментариев 14
2016-12-13 14:08:30Рейтинг 0

Прошу написать советник. Комментариев 8
2016-08-08 14:02:23Рейтинг 0

Добавить индикатор Parabolic SAR в советник Комментариев 3
2021-12-23 23:27:28Рейтинг 0

Робот по Super Arrow Indicator Комментариев 5
2016-10-21 12:01:13Рейтинг 0

Советник MTF_PSAR

Уважаемый Андрей!
Напишите пожалуйста советник по техзаданию.

Торговый советник
на пользовательском индикаторе MTF_PSAR
Stoploss
Takeprofit
TrailingStop
Фиксированный лот,
Shift
Начало работы советника /час, мин 00-00/
Окончание работы советник /час, мин 00-00/
Функция выхода из позиции перед окончанием работы советника
MagicNamber
1. Условия входа и выхода

а)Вход в длинную позицию осуществляется по следующему условию:
Рыночная цена больше значения MTF_PSAR.

Выход из длинной позиции
происходит, если выполнено, хотя бы одно из следующих условий:
•Выполнены условия для входа в короткую позицию.
•Выход по ордеру стоп-лосс или тейк-профит.
ПОСЛЕ ВЗЯТИЯ ТЕЙКПРОФИТА СОВЕТНИК В ПОЗИЦИЮ НЕ ЗАХОДИТ
А ЖДЕТ СЛЕДУЮЩЕГО СИГНАЛА.
•Выход в конце работы робота (при активной соответствующей опции).

б)Вход в короткую позицию осуществляется по следующему условию:
Рыночная цена меньше значения MTF_PSAR.

Выход из короткой позиции
происходит, если выполнено, хотя бы одно из следующих условий:
1. Выполнены условия для входа в длинную позицию.
2. Выход по ордеру стоп-лосс или тейк-профит.
ПОСЛЕ ВЗЯТИЯ ТЕЙКПРОФИТА СОВЕТНИК В ПОЗИЦИЮ НЕ ЗАХОДИТ
А ЖДЕТ СЛЕДУЮЩЕГО СИГНАЛА.
3.Выход в конце работы робота (при активной соответствующей
опции).

MTF_PSar.mq4 (2 Kb)
  • +1
  • Просмотров: 3337
  • 3 ноября 2016, 18:26
  • River
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Советник для MT4, работающий с мувингами
Следующая запись в группе  
Советник «POKER» (MQL5)
02 ноября 2016
05 ноября 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (3)

+
0
А чем ваш индикатор отличается от стандартного параболика? Бросил оба на график все один в один.
avatar

  35  AM2 Сообщений: 16265 - Андрей

  • 3 ноября 2016, 19:52
+
0
Сделал с вашим: www.opentraders.ru/downloads/1381/
Если мультитаймфреймовость не используется лучше будет работать со стандартным.



//+------------------------------------------------------------------+
//|                                                         PSAR.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 222;      // лось
extern int TakeProfit    = 222;      // язь
extern int TrailingStop  = 0;        // трал
extern int TrailingStep  = 20;       // шаг трала
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int CloseOn       = 1;        // 1-закрытие в конце работы
extern int Magic         = 123;      // магик

extern string IndName    = "MTF_PSar";
extern int    TimeFrame  = 0;
extern double Step       = 0.02;
extern double Maximum    = 0.2;

datetime t=0;
bool b=true,s=true;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2009                                                     |
//|  Описание : Возвращает флаг разрешения торговли по времени.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    hb - часы времени начала торговли                                       |
//|    mb - минуты времени начала торговли                                     |
//|    he - часы времени окончания торговли                                    |
//|    me - минуты времени окончания торговли                                  |
//+----------------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double sar=iCustom(NULL,0,IndName,TimeFrame,Step,Maximum,0,Shift);

   if(t!=Time[0])
     {
      if(Ask>sar && b)
        {
         PutOrder(0,Ask);
         b=false;
         s=true;
        }

      if(Bid<sar && s)
        {
         PutOrder(1,Bid);
         s=false;
         b=true;
        }
      t=Time[0];
     }
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos()
  {
   double sar=iCustom(NULL,0,IndName,TimeFrame,Step,Maximum,0,Shift);

   if(Bid>sar && CountOrders(1)>0)
     {
      CloseAll(1);// sell close
     }

   if(Ask<sar && CountOrders(0)>0)
     {
      CloseAll(0);//buy close
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderType()==OP_BUY)
           {
            if(Bid-OrderOpenPrice()>TrailingStop*Point)
              {
               if(OrderStopLoss()<Bid-(TrailingStop+TrailingStep-1)*Point)
                 {
                  mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }

         if(OrderType()==OP_SELL)
           {
            if((OrderOpenPrice()-Ask)>TrailingStop*Point)
              {
               if(OrderStopLoss()>Ask+(TrailingStop+TrailingStep-1)*Point || OrderStopLoss()==0)
                 {
                  mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Закрытие позиции по типу ордера                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1 && isTradeTimeInt(StartHour,StartMin,EndHour,EndMin))
     {
      OpenPos();
     }
   else ClosePos();

   if(!isTradeTimeInt(StartHour,StartMin,EndHour,EndMin) && CloseOn>0) CloseAll();

   if(TrailingStop>0) Trailing();
  }
//+------------------------------------------------------------------+

Редактирован: 6 ноября 2016, 17:49
avatar

  35  AM2 Сообщений: 16265 - Андрей

  • 3 ноября 2016, 20:29
+
0
MTF обязательно используется!!!
avatar

  9  River Автор Сообщений: 90

  • 3 ноября 2016, 20:45

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий