Андрей, Здравствуйте !, доработайте пожалуйста Ваш советник, размещенный ранее в одном из топиков, в виде кода…
Напомню алгоритм на данный момент:"- По сигналу индикатора(смена цвета-тренда) ставится один ордер(на пример sell), в случае если ордер не сработал по прибыли в валюте депозита… а появился сигнал противоположного направления то сов открывает второй ордер(bay) с удвоенным лотом… и так до тех пор пока не закроет все ордера по общей прибыли (Profit) указанной в валюте депозита. C первой позиции или с 5-6, только при достижении указанного профита все ордера по паре закрываются и ждет новый сигнал..."
Теперь нужно изменить и добавить:
1) «Profit» указанный в валюте депозита.-- должен включаться только при условии, что появился второй ордер!, профит в валюте депозита должен работать ТОЛЬКО НА ВСЮ СЕРИЮ ордеров, то есть он включается если открыто больше одного ордера: два, три и т.д.… десять. Если открыт ОДИН ордер, то работает обычный (TakeProfit) или (StopLoss)!!..

2)После закрытия серии ордеров по профиту в валюте депозита или закрытия одного ордера(когда он один) по tp/sl, должен сразу же открыться новый ордер текущего тренда(по цвету индикатора)!..

3)Если нетрудно: «индюка» BBands_Stop_v1.mq4 (5 Kb) BBands_Stop_v1.ex4 (7 Kb)«зашить» в «сову» и вывести в настройки три параметра:

Настройки BBands_Stop_v1:
Length = 20; // период BB
Deviation = 2; // отклонение ВВ
MoneyRisk =10;

Все остальное уже есть в Вашем исходном коде:

//+------------------------------------------------------------------+
//|                                                         ExBB.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property description "BBands expert advisor"

//--- Inputs
extern double Lots         = 0.1;  // лот
extern double KLot         = 2;    // умножение лота
extern double MaxLot       = 5;    // максимальный лот
extern int    StopLoss     = 5000; // лось
extern int    TakeProfit   = 5000; // язь
extern double Profit       = 50;   // язь в рублях
extern int    Shift        = 1;    // сдвиг
extern int    Slip         = 30;   // слипаж
//----
extern int    Length       = 20;   // период BB 
extern int    Deviation    = 2;    // отклонение ВВ
extern int    Magic        = 20;   // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)   sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)   sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY || OrderType()==OP_SELL) count++;
           }
        }
     }
   return(count);
  }  
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   if(CountTrades()>0) lot=NormalizeDouble(Lots*MathPow(KLot,CountTrades()),2);
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll()
  {
   bool cl;

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY) cl=OrderClose(OrderTicket(),OrderLots(),Bid,Slip,Blue);
            if(OrderType()==OP_SELL) cl=OrderClose(OrderTicket(),OrderLots(),Ask,Slip,Red);
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double AllProfit()
  {
   double profit=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY || OrderType()==OP_SELL) profit+=OrderProfit()+OrderSwap()+OrderCommission();
           }
        }
     }
   return (profit);
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
//--- get Ind
   double BBBlue=iCustom(Symbol(),0,"BBands_Stop_v1",Length,Deviation,0,Shift);
   double BBRed=iCustom(Symbol(),0,"BBands_Stop_v1",Length,Deviation,1,Shift);
   double BBBlue2=iCustom(Symbol(),0,"BBands_Stop_v1",Length,Deviation,0,Shift+1);
   double BBRed2=iCustom(Symbol(),0,"BBands_Stop_v1",Length,Deviation,1,Shift+1);
   
//--- sell conditions
   if(BBRed>0 && BBBlue2>0)
     {
      PutOrder(1,Bid);
     }
//--- buy conditions
   if(BBBlue>0 && BBRed2>0)
     {
      PutOrder(0,Ask);
     }
//---
  }
//+------------------------------------------------------------------+
//| OnTick function                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      OpenPos();
      t=Time[0];
     }
     
     if(AllProfit()>Profit) CloseAll();
     Comment("\n Profit: ",AllProfit());
  }
//+------------------------------------------------------------------+

За ранее благодарю.