beton2011

 
Уровень 14
Добро пожаловать в мой блог!

  Моя торговля


График торгового счета beton2011


Группа "Стол заказов MQL"

Рейтинг 2081


Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 1000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от beton2011



Советник STX Комментариев 177
2015-03-22 12:25:08Рейтинг 0

Советник BB Time Комментариев 6
2016-10-22 11:57:11Рейтинг 0

Советник по индикатору МА с уровнями. Комментариев 10
2017-03-05 18:34:48Рейтинг 0

Советник Игрок с хитрым мартингейлом Комментариев 14
2017-01-02 15:08:13Рейтинг 0

Советник 9-9-9 Комментариев 22
2016-08-30 18:18:41Рейтинг 0

Переделать советник

Андрей здравствуйте.

Можно попросить переделать этот советник www.opentraders.ru/downloads/1400/ хочется посмотреть как будет работать советник со стоповыми ордерами, должен получится неплохой пробойник :D 

Спасибо.
  • +3
  • Просмотров: 2646
  • 27 ноября 2016, 21:28
  • beton2011
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
Следующая запись в группе  
Исправить советник.
27 ноября 2016
28 ноября 2016

Комментарии (6)

+
0
Завтра буду смотреть.
avatar

  34  AM2 Сообщений: 15871 - Андрей

  • 27 ноября 2016, 21:30
+
0
Как там продвигаются дела с переделкой советника? Еще такой вопрос, как определяется волатильность в советнике? Че то про это нигде не написано на этом сайте.
avatar

  14  beton2011 Автор Сообщений: 895

  • 28 ноября 2016, 13:13
  • ↑
+
0
Только что доделал:


//+------------------------------------------------------------------+
//|                                                       Bablos.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

extern int    StopLoss     = 500;      // лось
extern int    TakeProfit   = 10;       // язь
extern int    Delta        = 10;       // расстояние для отложек
extern int    Spread       = 10;       // спред
extern int    Vol          = 40;       // волатильность
extern int    Slip         = 0;        // реквот
extern int    StartHour    = 0;        // час начала торговли
extern int    StartMin     = 30;       // минута начала торговли
extern int    EndHour      = 23;       // час окончания торговли
extern int    EndMin       = 30;       // минута окончания торговли
extern int    StopTrade    = 0;        // 1-остановка после закрытия всех ордеров
extern int    Magic1       = 111;      // магик 1
extern int    Magic2       = 222;      // магик 2
extern double Lots         = 0.1;      // лот

bool trade=true;
int cycle=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price,int magic)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Подсчет позиций                                                  |
//+------------------------------------------------------------------+
int CountTrades(int ot=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==0 && (ot==0 || ot==-1)) count++;
            if(OrderType()==1 && (ot==1 || ot==-1)) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ModifyOrders(int magic)
  {
   double all=0,tp=0,sl=0;
   double count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==magic)
           {
            if(OrderType()==OP_BUY || OrderType()==OP_SELL)
              {
               all+=OrderOpenPrice()*OrderLots();
               count+=OrderLots();
              }
           }
        }
     }
   if(count>0) all=NormalizeDouble(all/count,Digits);

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==magic)
           {
            if(OrderType()==OP_BUY)
              {
               tp=NormalizeDouble(all+TakeProfit*Point,Digits);
               sl=NormalizeDouble(all-StopLoss*Point,Digits);
               if(OrderStopLoss()!=sl || OrderTakeProfit()!=tp)
                  bool mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
              }
            if(OrderType()==OP_SELL)
              {
               tp=NormalizeDouble(all-TakeProfit*Point,Digits);
               sl=NormalizeDouble(all+StopLoss*Point,Digits);
               if(OrderStopLoss()!=sl || OrderTakeProfit()!=tp)
                  bool mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Mode()
  {
   bool m;
   double oop=0,sl=0,tp=0;

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==5)
              {
               if(Ask-Delta*Point>OrderOpenPrice())
                 {
                  oop=NormalizeDouble(Ask-Delta*Point,Digits);
                  if(StopLoss>0) sl=NormalizeDouble(oop+StopLoss*Point,Digits);
                  if(TakeProfit>0) tp=NormalizeDouble(oop-TakeProfit*Point,Digits);
                  if(OrderOpenPrice()!=oop) m=OrderModify(OrderTicket(),oop,sl,tp,OrderExpiration(),Lime);
                 }

              }

            if(OrderType()==4)
              {
               if(OrderOpenPrice()-Ask>Delta*Point)
                 {
                  oop=NormalizeDouble(Ask+Delta*Point,Digits);
                  if(StopLoss>0) sl=NormalizeDouble(oop-StopLoss*Point,Digits);
                  if(TakeProfit>0) tp=NormalizeDouble(oop+TakeProfit*Point,Digits);
                  if(OrderOpenPrice()!=oop) m=OrderModify(OrderTicket(),oop,sl,tp,OrderExpiration(),Lime);
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double vol=MathAbs((Open[0]-Close[0])/Point);
   double spread=MarketInfo(NULL,MODE_SPREAD);

   if(cycle>0 && CountTrades()<1 && StopTrade>0) trade=false;

   if(trade)
     {
      if(vol>Vol && isTradeTimeInt(StartHour,StartMin,EndHour,EndMin) && spread<=Spread)
        {
         if(CountOrders(4)<1) PutOrder(4,Bid+Delta*Point,Magic1);
         if(CountOrders(5)<1) PutOrder(5,Bid-Delta*Point,Magic2);
        }

      if(CountOrders(0)>0) ModifyOrders(Magic2);
      if(CountOrders(1)>0) ModifyOrders(Magic1);

      Mode();
      if(CountTrades()>0) cycle++;
     }

   Comment("\n Trades: ",CountTrades(),
           "\n Vol: ",NormalizeDouble(vol,1),
           "\n Spread: ",spread,
           "\n Cycle: ",cycle,
           "\n Trade: ",trade);
  }
//+------------------------------------------------------------------+
avatar

  34  AM2 Сообщений: 15871 - Андрей

  • 28 ноября 2016, 19:35
  • ↑
+
0
Еще такой вопрос, как определяется волатильность в советнике? 


double vol=MathAbs((Open[0]-Close[0])/Point);
avatar

  34  AM2 Сообщений: 15871 - Андрей

  • 28 ноября 2016, 19:41
  • ↑
+
0
Спасибо. Не знаю, возможно это просто совпадение, но я уже хотел вас просить сделать с нуля такой советник, а здесь вдруг появился похожий но только надо было переделать *good* 

Позже буду тестировать советник.
Редактирован: 28 ноября 2016, 21:22
avatar

  14  beton2011 Автор Сообщений: 895

  • 28 ноября 2016, 21:22
  • ↑
+
0
теоретически они будут скользить :) 
avatar

  10  cardon Сообщений: 376

  • 27 ноября 2016, 21:45

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари