ruslan71
Руслан

 
Уровень 22
Добро пожаловать в мой блог!

  Торгую в компаниях:


Группа "Стол заказов MQL"

Рейтинг 2161


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

доработка совы
[*]

Андрей просьба добавить в эту совуMissMarple.mq4 (4 Kb) MissMarple.ex4 (10 Kb) функцию закрытие сделки по обратному сигналу индикатора тоесть если тейк выставляем 0 то работает закрытие по обратному если тейк выставляем в пунктах то закрываем по тейку скрин прилогаю

это для покупок для продаж все наоброт
  • +1
  • Просмотров: 1753
  • 4 декабря 2016, 23:56
  • ruslan71
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Доработка советника Merkio.
Следующая запись в группе  
Сова для МТ5 на основе осциллятора WO.
04 декабря 2016
05 декабря 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (2)

+
0
Сделал закрытие по сигналу:

extern int CloseSig = 0; // 1-закрытие по сигналу





//+------------------------------------------------------------------+
//|                                                   MissMarple.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern string StartTime  = "00:00";  // время начала торговли
extern string EndTime    = "23:00";  // время окончания торговли
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int Slip          = 30;       // реквот
extern int MAPeriod      = 12;       // период МА
extern int WPRPeriod     = 21;       // период WPR
extern int WPRLevel      = 5;        // уровень WPR
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int OnePos        = 1;        // 1-одна поза 0-несколько
extern int CloseSig      = 0;        // 1-закрытие по сигналу
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderProfit()<0)
        {
         lot=OrderLots()*KLot;
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double ma=iMA(NULL,0,MAPeriod,0,0,0,Shift);
   double wpr1=iWPR(NULL,0,WPRPeriod,Shift);
   double wpr2=iWPR(NULL,0,WPRPeriod,Shift+1);

   if(Ask>ma && wpr1>-100+WPRLevel && wpr2<-100+WPRLevel)
     {
      PutOrder(0,Ask);
     }

   if(Bid<ma && wpr2>-WPRLevel && wpr1<-WPRLevel)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos()
  {
   double ma=iMA(NULL,0,MAPeriod,0,0,0,Shift);
   double wpr1=iWPR(NULL,0,WPRPeriod,Shift);
   double wpr2=iWPR(NULL,0,WPRPeriod,Shift+1);
//---
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(wpr2>-WPRLevel && wpr1<-WPRLevel)
                 {
                  CloseAll(0);
                 }
              }
            if(OrderType()==OP_SELL)
              {
               if(wpr1>-100+WPRLevel && wpr2<-100+WPRLevel)
                 {
                  CloseAll(1);
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   datetime End=StringToTime(EndTime);
   datetime Start=StringToTime(StartTime);

   if(TimeCurrent()>Start && TimeCurrent()<End)
     {
      if(t!=Time[0] && OnePos<1)
        {
         OpenPos();
         t=Time[0];
        }

      if(CountTrades()<1 && OnePos>0) OpenPos();
      if(CloseSig>0) ClosePos();
     }
  }
//+------------------------------------------------------------------+

Редактирован: 5 декабря 2016, 12:35
avatar

  35  AM2 Сообщений: 16665 - Андрей

  • 5 декабря 2016, 11:59
+
0
Андрей спасибо
avatar

  22  ruslan71 Автор Сообщений: 1009 - Руслан

  • 5 декабря 2016, 15:49

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий