Советник анализирует соотношение размера тела свечи в размеру самой свечи и если тело свечи большое, т.е. 70 и более процентов от всей свечи (процент соотношения размера тела можно выставить в настройках чтобы посмотреть результаты с большим минимальным процентом пропорции), то дальше он анализирует вторую свечу и если она закрывается в противоположном направлении и тоже с крупным телом (70% и более), то это рельсы и выставляется отложка на экстримум свечи, которая удаляется через 5 свечей.

здесь также нужно будет учесть размер свечи в пунктах а то рельсы будут очень маленькими

//+------------------------------------------------------------------+
//|                                                        Rails.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 50;       // лось
extern int TakeProfit    = 70;       // язь
extern int Expiration    = 5;        // истечение ордера
extern int Delta         = 100;      // дельта
extern int Points        = 30;       // разница
extern int Body          = 50;       // тело свечи
extern int Procent       = 70;       // процент для тела свечи
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderProfit()<0)
        {
         lot=OrderLots()*KLot;
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,TimeCurrent()+Expiration*3600,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int UpRail()
  {
   int up=0;
   if(MathAbs(Open[2]-Close[1])<Points*Point && MathAbs(Close[2]-Open[1])<Points*Point && Close[1]-Open[1]>0
   && MathAbs(Close[1]-Open[1])>Body*Point
   && (Open[2]-Close[2])/(High[2]-Low[2])>Procent*0.01 && (Close[1]-Open[1])/(High[1]-Low[1])>Procent*0.01) up=1;
   return(up);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int DnRail()
  {
   int up=0;
   if(MathAbs(Close[2]-Open[1])<Points*Point && MathAbs(Open[2]-Close[1])<Points*Point && Close[1]-Open[1]<0
   && MathAbs(Close[1]-Open[1])>Body*Point
   && (Close[2]-Open[2])/(High[2]-Low[2])>Procent*0.01 && (Open[1]-Close[1])/(High[1]-Low[1])>Procent*0.01) up=1;
   return(up);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0] && (CountOrders(0)<1 && CountOrders(1)<1))
     {
      if(CountOrders(4)<1 && UpRail()>0 && Bid<High[1]) PutOrder(4,High[1]+Delta*Point);
      if(CountOrders(5)<1 && DnRail()>0 && Bid>Low[1]) PutOrder(5,Low[1]-Delta*Point);
      t=Time[0];
     }

   Comment("\n ");
  }
//+------------------------------------------------------------------+