sledopyt

 
Уровень 12
Добро пожаловать в мой блог!


Группа "Стол заказов MQL"

Рейтинг 2156


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от sledopyt



Советник на пробой-отбой уровня с переворотом и мартингейлом Комментариев 43
2021-09-12 10:32:40Рейтинг 0

Двухлинейный усреднитель Комментариев 6
2020-03-26 14:52:19Рейтинг 0

Простой советник Мышеловка на отложенных ордерах Комментариев 9
2021-10-12 18:17:09Рейтинг 0

Самовыставляющий советник Комментариев 20
2021-11-27 13:29:28Рейтинг 0

Доработка советника «Para Otlog»

Прошу доработать советник «Para Otlog» www.opentraders.ru/downloads/1742/
Суть доработки в следующем: при открытии первого стоп-ордера второй стоп-ордер переносится к уровню открытия свечи. Параметры профита и лосса не меняются.
  • 0
  • Просмотров: 4670
  • 14 февраля 2018, 14:43
  • sledopyt
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Доделать созданного эксперта
Следующая запись в группе  
советник
14 февраля 2018
15 февраля 2018

Брокер для ваших роботов, 15 лет на рынке

Комментарии (17)

+
0
не раньше следующей недели доберусь.
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 14 февраля 2018, 18:04
+
0
Отсрочка, не отказ, и это главное.
avatar

  12  sledopyt Автор Сообщений: 151

  • 14 февраля 2018, 18:06
  • ↑
+
0
И еще все подробно на скринах. Это увеличит шансы получить советник в готовом виде.
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 14 февраля 2018, 18:08
  • ↑
0
Подробно выглядит следующим образом. Пошаговое исполнение.
avatar

  12  sledopyt Автор Сообщений: 151

  • 14 февраля 2018, 18:40
  • ↑
0
*good*  *yes* 
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 14 февраля 2018, 19:28
+
0
Установился, открылся, перенес: 




//+------------------------------------------------------------------+
//|                                                    ParaOtlog.mq4 |
//|                                              Copyright 2018, AM2 |
//|                                      http://www.forexsyatems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, AM2"
#property link      "http://www.forexsyatems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 300;      // лось
extern int TakeProfit    = 400;      // язь
extern int Slip          = 30;       // реквот
extern int Delta         = 100;      // расстояние от цены
extern int Exp           = 10;       // истечение в часах
extern int Magic         = 123;      // магик

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,TimeCurrent()+Exp*3600,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Mode(double op)
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderOpenPrice()!=op)
              {
               if(OrderType()==4)
                 {
                  m=OrderModify(OrderTicket(),op,op-StopLoss*Point,op+TakeProfit*Point,OrderExpiration(),Yellow);
                  return;
                 }
               if(OrderType()==5)
                 {
                  m=OrderModify(OrderTicket(),op,op+StopLoss*Point,op-TakeProfit*Point,OrderExpiration(),Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double open=iOpen(NULL,PERIOD_D1,0);

   if(CountOrders(-1)<1)
     {
      if(CountOrders(4)<1 && Bid-open<Delta*Point) PutOrder(4,open+Delta*Point);
      if(CountOrders(5)<1 && open-Bid<Delta*Point) PutOrder(5,open-Delta*Point);
     }

   if(CountOrders(0)>0 || CountOrders(1)>0)
     {
      Mode(open);
     }
  }
//+------------------------------------------------------------------+


Редактирован: 19 февраля 2018, 20:54
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 19 февраля 2018, 20:46
0
Сейчас проверим, есть ли в этом система или это единичный случай.
avatar

  12  sledopyt Автор Сообщений: 151

  • 19 февраля 2018, 20:49
  • ↑
0
При тестировании в тестере обнаружил, что пропала функция старого советника, при которой все закрывается при закрытии текущей свечи (в данном случае дневной), а на новой свече цикл начинается сначала. Новая функция «срок истечения 10 часов» не сработала и стоп-ордер стоит неделю.


или до тех пор, пока цена его не активирует.

Редактирован: 19 февраля 2018, 21:13
avatar

  12  sledopyt Автор Сообщений: 151

  • 19 февраля 2018, 21:06
  • ↑
+
0
что пропала функция старого советника

я с нуля писал по тому что нарисовали. если добавлять еще неизвестно как впишется новая функция в советник.
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 19 февраля 2018, 21:43
комментарий был удален 2018-02-19 22:14:55 sledopyt

0
Знал бы я, что с нуля будет проще написать, то написал бы ТЗ подробнее. Я его
хотел проверить на совместимость с индикатором OpenDelta. Но линии рисуются в начале каждого дня, а стоповые ордера остаются далеко позади. А по идее должны каждый день устанавливаться заново и совпадать с линиями индикатора как в советнике ParaOtlog.

avatar

  12  sledopyt Автор Сообщений: 151

  • 19 февраля 2018, 22:14
0
Поставил срок истечения 3 часа. Но стоп-ордер благополучно пережил семь сроков истечения.

И только на восьмом сроке он исчез и установились два новых.

Редактирован: 19 февраля 2018, 22:39
avatar

  12  sledopyt Автор Сообщений: 151

  • 19 февраля 2018, 22:37
+
0
Но стоп-ордер благополучно пережил семь сроков истечения

На скрине ордер удаляется и ставится заново, т.к. нет никаких других условий в тз.
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 20 февраля 2018, 17:22
0
Тогда встречаемся в следующем месяце.
avatar

  12  sledopyt Автор Сообщений: 151

  • 20 февраля 2018, 18:57
  • ↑
+
0
Я попытался вписать функцию, но советник ссылку на который вы мне дали заточен под совершенно другое тз.




//+------------------------------------------------------------------+
//|                                                    ParaOtlog.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsyatems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsyatems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 300;      // лось
extern int TakeProfit    = 400;      // язь
extern int Slip          = 30;       // реквот
extern int Delta         = 100;      // расстояние от цены
extern int Type          = 0;        // 0-stop 1-limit
extern int Del           = 1;        // 1-удалять другую
extern int Mod           = 1;        // 1-модим ордер
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   for(int i=OrdersHistoryTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY))
        {
         if(OrderProfit()>0) break;
         if(OrderProfit()<0)
           {
            lot=OrderLots()*KLot;
            break;
           }
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//| Удаление отложенных ордеров                                      |
//+------------------------------------------------------------------+
void DelOrder()
  {
   bool del;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()>1) del=OrderDelete(OrderTicket());
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Mode(double op)
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderOpenPrice()!=op)
              {
               if(OrderType()==4)
                 {
                  m=OrderModify(OrderTicket(),op,op-StopLoss*Point,op+TakeProfit*Point,OrderExpiration(),Yellow);
                  return;
                 }
               if(OrderType()==5)
                 {
                  m=OrderModify(OrderTicket(),op,op+StopLoss*Point,op-TakeProfit*Point,OrderExpiration(),Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double open=iOpen(NULL,PERIOD_D1,0);

   if(CountOrders(0)>0 || CountOrders(1)>0)
     {
      if(Mod>0) Mode(open);
     }

   if(t!=Time[0])
     {
      CloseAll();

      if(Type==0)
        {
         if(Bid-open<Delta*Point) PutOrder(4,open+Delta*Point);
         if(open-Bid<Delta*Point) PutOrder(5,open-Delta*Point);
        }

      if(Type==1)
        {
         if(Bid-open<Delta*Point) PutOrder(3,open+Delta*Point);
         if(open-Bid<Delta*Point) PutOrder(2,open-Delta*Point);
        }
      t=Time[0];
     }

   if(Del>0 && CountTrades()>0) DelOrder();
  }
//+------------------------------------------------------------------+

avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 20 февраля 2018, 20:19
0
Там в топике было следующее ТЗ:
На открытии бара ставит две отлоги
Когда одна сработала, вторую удаляет или оставляет
На открытии нового бара:
а) отлоги удаляет
б) имеющиеся сделки закрывает
в) ставит новые отлоги
Вот я и предположил, что будет легко изменить только одну строчку на
Когда одна сработала, вторую удаляет или переставляет на цену открытия
Оказалось, что был глубоко не прав.
Пытался вставить имеющийся в том топике новый отрезок кода, но не получилось.

Ваша новая версия, которая устанавливает стоп-ордера от цены открытия дня на любом ТФ мне нравится гораздо больше. Но в ней нет следующих функций:
На открытии нового дня:
а) отлоги удаляет
б) имеющиеся сделки закрывает
в) ставит новые отлоги
Буду на ее основе новое, подробное ТЗ составлять. В следующем месяце буду делать новый заказ.

Редактирован: 20 февраля 2018, 21:36
avatar

  12  sledopyt Автор Сообщений: 151

  • 20 февраля 2018, 21:35
  • ↑
0
а) отлоги удаляет
б) имеющиеся сделки закрывает


есть. отключаемая функция.

На открытии нового дня:


ставьте на д1
avatar

  35  AM2 Сообщений: 16537 - Андрей

  • 20 февраля 2018, 21:41

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Загрузка...