Группа "Стол заказов MQL"

Рейтинг 2073



РЕКОМЕНДУЮ



RSI + AC + SMA

Тезка доброго времени суток!
Хотелось бы сову по следующему ТЗ:
Вход на закрывшейся свече при условии — 1) RSI пересек уровень 50 и закрепился (выше или ниже); 2) фильтр индикатор АС того же цвета что и направление пересечения RSI (RSI выше 50 — зеленый АС, RSI ниже 50 — красный АС); 3) цена закрепилась выше или ниже SMA 5.

RSI с периодом 5 и уровнем 50
SMA с периодом 5


Настройки советника:
— TP;
— SL;
— размер лота;
— проскальзывание.

Если сможешь буду признателен.

P.S. В архиве шаблон…
RSI + AC + SMA.zip (0 Kb)
  • 0
  • Просмотров: 3792
  • 2 сентября 2018, 19:55
  • poker
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Добавить в советник пару фишек
Следующая запись в группе  
Cова по ТЗ на двух индюках
02 сентября 2018
03 сентября 2018

Комментарии (8)

+
+1
на 10-е
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 2 сентября 2018, 21:21
+
+1
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 5 сентября 2018, 23:36
+
0
Тезка, привет!
Скажи, а сложно допилить немного сову… не учел один момент…
Если я ставлю сову на D1 к примеру, то с малым язем достигаем профита, закрываем позу и тут же опять открываем (ну это и понятно — сигнал то никуда не пропал). Можно, чтобы сова открывала (или выполняла) сигнал только 1 раз на свече. Спасибо.
P.S. Просто цена уходит и самый последний открытый лот как правило убыточный — там разворот бывает ) если ставлю большого лося, много теряю.
Тестирую )))

Редактирован: 9 сентября 2018, 13:10
avatar

  22  poker Автор Сообщений: 795

  • 9 сентября 2018, 13:04
+
+1
варик с открытием свечи:


//+------------------------------------------------------------------+
//|                                                         Poka.mq4 |
//|                                              Copyright 2018, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 2;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int MAPeriod      = 5;        // период МА
extern int RSIPeriod     = 14;       // период RSI
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits); else sl=NormalizeDouble(Close[1]+MarketInfo(NULL,MODE_STOPLEVEL)*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits); else sl=NormalizeDouble(Close[1]-MarketInfo(NULL,MODE_STOPLEVEL)*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   for(int i=OrdersHistoryTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderProfit()>0) break;
            if(OrderProfit()<0)
              {
               lot=OrderLots()*KLot;
               break;
              }
           }
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double ac1=iAC(NULL,0,Shift);
   double ac2=iAC(NULL,0,Shift+1);
   double ma=iMA(NULL,0,MAPeriod,0,0,0,Shift);
   double rsi1=iRSI(NULL,0,RSIPeriod,0,Shift);
   double rsi2=iRSI(NULL,0,RSIPeriod,0,Shift+1);

   if(Bid>ma && rsi1>50 && rsi2<50 && ac1>ac2) PutOrder(0,Ask);
   if(Bid<ma && rsi1<50 && rsi2>50 && ac1<ac2) PutOrder(1,Bid);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      if(CountTrades()<1) OpenPos();
      t=Time[0];
     }
  }
//+------------------------------------------------------------------+

avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 10 сентября 2018, 20:11
+
0
Спасибо! ;) 
avatar

  22  poker Автор Сообщений: 795

  • 12 сентября 2018, 21:11
+
0
Андрей, поместите последний вариант (открытие на 1 свече) в файлы, а то я не силен в прогах, самому не исправить в коде. Спасибо.
avatar

  11  Sam34 Сообщений: 143 - Sem34

  • 12 сентября 2018, 21:34
+
0
Как то так получилось…
Во вложении архив с файлами.
cloud.mail.ru/public/9DLf/NchidLVt6
avatar

  22  poker Автор Сообщений: 795

  • 12 сентября 2018, 22:29
+
0
Спасибо. Потестим.)
avatar

  11  Sam34 Сообщений: 143 - Sem34

  • 12 сентября 2018, 22:32

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари