sergs
Сергей

 
Уровень 5


Группа "Стол заказов MQL"

Рейтинг 1464



РЕКОМЕНДУЮ




Лучшее от sergs



Советник на одной МА Комментариев 10
2019-11-01 06:43:29Рейтинг 0

Простой советник на одной МА

Советник использует для торговли стандартную МА(35,0,Simple) на разных таймфреймах. Если все машки на выбранных таймфреймах смотрят вверх — покупаем. Если вниз — продаем. Закрытие по стопу или тейку. Один график — одна позиция.
Настройки: лот, стоп, тейк, период МА. Далее в каждой строчке все таймфреймы с переключателями Вкл./Выкл. Вкл. — использовать таймфрейм в торговле, Выкл. — не использовать. Все.
  • 0
  • Просмотров: 648
  • 1 декабря 2019, 08:14
  • sergs
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Сделать советтник для теста на истории
Следующая запись в группе  
Старое по-новой
01 декабря 2019
01 декабря 2019

Комментарии (18)

+
0
из 9-ти чисел сколько комбинаций мне придется прописывать посчитали?
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 08:58
+
0
9^9=387420489 *crazy*  *shock*  *spokuha* 
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 09:09
+
0
Не знал, что каждую комбинацию нужно прописывать отдельно. Достаточно одной: от М1 до Н1.
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 1 декабря 2019, 09:15
+
0
когда вкл, выкл так и получится. если 2 тф старший и младший, так еще реально написать
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 09:48
+
0
А если 5 таймфреймов? все машки вверх — одна комбинация. все вниз — вторая. это нереально?
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 1 декабря 2019, 09:54
+
0
для 5 тф только 10 вызовов индикаторов надо делать и еще неизвестно что там по ходу выполнения всплывет
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 10:03
+
0
А как же вот это: forexdengi.com/threads/65933-torgovaya-panel-dlya-binarnih-optsionov?thread_type=0? Там все таймфреймы и 6 индикаторов.
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 1 декабря 2019, 10:35
+
0
делаю только то что можно быстро сделать
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 11:57
+
0
на 10-е
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 1 декабря 2019, 20:29
+
0
Андрей, добавь в настройки сдвиг и метод МА.
Редактирован: 6 декабря 2019, 13:44
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 2 декабря 2019, 15:24
комментарий был удален 2019-12-06 13:41:29 sergs

+
0
А также безубыток и трал.
Редактирован: 6 декабря 2019, 13:45
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 3 декабря 2019, 10:43
+
0
А если 5 таймфреймов? все машки вверх — одна комбинация. все вниз — вторая. это нереально?


ни одной сделки, вот код:


//+------------------------------------------------------------------+
//|                                                          MA5.mq4 |
//|                                              Copyright 2019, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2019, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots        = 0.1;      // лот
extern double Risk        = 0;        // >0 риск
extern int StopLoss       = 1500;     // лось
extern int TakeProfit     = 2000;     // язь
extern int BULevel        = 0;        // уровень БУ
extern int BUPoint        = 30;       // пункты БУ
extern int TrailingStop   = 0;        // трал
extern int Slip           = 30;       // реквот
extern int Shift          = 1;        // на каком баре сигнал индикатора
extern int Magic          = 123;      // магик

extern int MAPeriod       = 35;       // период МА
extern int MAShift        = 0;        // сдвиг МА
extern ENUM_MA_METHOD MAMethod = 0;   // метод МА
extern ENUM_APPLIED_PRICE MAPrice = 0; // цены МА

extern ENUM_TIMEFRAMES TF1 = 1;       // M1
extern ENUM_TIMEFRAMES TF2 = 5;       // M5
extern ENUM_TIMEFRAMES TF3 = 15;      // M15
extern ENUM_TIMEFRAMES TF4 = 30;      // M30
extern ENUM_TIMEFRAMES TF5 = 60;      // H1

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Закрытие позиции по типу ордера                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*_Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*_Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*_Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*_Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*_Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*_Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   double MaxLot=MarketInfo(NULL,MODE_MAXLOT);
   if(Risk>0)
      lot=AccountBalance()*Risk/100000;// 10000*Risk/100000=1
   if(lot>MaxLot)
      lot=MaxLot;
   return(lot);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double ma1=iMA(NULL,TF1,MAPeriod,MAShift,MAMethod,MAPrice,Shift);
   double ma2=iMA(NULL,TF2,MAPeriod,MAShift,MAMethod,MAPrice,Shift);
   double ma3=iMA(NULL,TF3,MAPeriod,MAShift,MAMethod,MAPrice,Shift);
   double ma4=iMA(NULL,TF4,MAPeriod,MAShift,MAMethod,MAPrice,Shift);
   double ma5=iMA(NULL,TF5,MAPeriod,MAShift,MAMethod,MAPrice,Shift);

   double ma12=iMA(NULL,TF1,MAPeriod,MAShift,MAMethod,MAPrice,Shift+1);
   double ma22=iMA(NULL,TF2,MAPeriod,MAShift,MAMethod,MAPrice,Shift+1);
   double ma32=iMA(NULL,TF3,MAPeriod,MAShift,MAMethod,MAPrice,Shift+1);
   double ma42=iMA(NULL,TF4,MAPeriod,MAShift,MAMethod,MAPrice,Shift+1);
   double ma52=iMA(NULL,TF5,MAPeriod,MAShift,MAMethod,MAPrice,Shift+1);

   if(BULevel>0)
      BU();
   if(TrailingStop>0)
      Trailing();

   if(CountTrades()<1)
     {
      if(ma1>ma12 && ma2>ma22 && ma3>ma32 && ma4>ma42 && ma5>ma52)
        {
         PutOrder(0,Ask);
        }
      if(ma1<ma12 && ma2<ma22 && ma3<ma32 && ma4<ma42 && ma5<ma52)
        {
         PutOrder(1,Bid);
        }
     }
  }
//+------------------------------------------------------------------+

avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 7 декабря 2019, 10:02
+
0
А тогда можно сменить задание?
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 7 декабря 2019, 10:12
+
0
можно сделать первые 4 М30 а 5-ю Н1, тогда получится отключение и сделки будут:



www.opentraders.ru/downloads/2500/
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 7 декабря 2019, 10:23
+
0
а зачем 4 одинаковых таймфрейма? тогда уж достаточно двух.
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 7 декабря 2019, 10:34
+
0
т.о. отключаются тф. как вы и просили
avatar

  29  AM2 Сообщений: 10063 - Андрей

  • 7 декабря 2019, 12:43
+
0
почему нет максимального объема сделок и как рассчитывается риск?
avatar

  5  sergs Автор Сообщений: 52 - Сергей

  • 7 декабря 2019, 10:51

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари