//+------------------------------------------------------------------+
//|                                               CPsar.mq4          |
//|                                              Copyright 2021,     |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.01;     // лот
extern double Profit     = 0.15;     // Суммарный профит
extern int Count         =10;        // макс.к-во ордеров
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик
extern string SAR        ="Настроки PSar";
extern double SarStep       =0.02;
extern double SarMax        =0.2;
extern int SarShift      =0;
extern string Comm       = "CPsar";   // коммент
double MINLOT,MAXLOT;
datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
 MINLOT = MarketInfo(Symbol(),MODE_MINLOT);
 MAXLOT = MarketInfo(Symbol(),MODE_MAXLOT);
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1)
     {
      clr=Red;
     }

   if(type==0)
     {
      clr=Blue;
     }
   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,Comm,Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   if (lot>MAXLOT) lot = MAXLOT;
   if (lot<MINLOT) lot = MINLOT;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (type==0 || type==-1))
              {
               count++;
              }
            if(OrderType()==1 && (type==1 || type==-1))
             {
               count++;
             }
           }
         }
       }
   return(count);
  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
    double sar=iSAR(NULL,0,SarStep,SarMax,SarShift);
    double sar2=iSAR(NULL,0,SarStep,SarMax,SarShift+1);
    
    if(AllProfit()>Profit && Profit>0)
     {
      CloseAll();
     }
    if(sar2>High[1] && sar<Bid)
     {
      CloseAll(1);
     }
    if(sar2<Low[1] && sar>Bid)
     {
      CloseAll(0);
     }
    if(t!=Time[0])
     {
     if(CountTrades()<Count)
       {
      if(sar<Bid)
       {
        PutOrder(0,Ask);
       }
      if(sar>Bid)
       {
        PutOrder(1,Bid);
       }
      t=Time[0];
     } 
    }    
 //--------------------------------------
   Comment("\n Trades: ",CountTrades());
   }
  
//+------------------------------------------------------------------+