//------------------------------------------------------------------
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"
//------------------------------------------------------------------
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   2
#property indicator_label1  "T3 velocity histo"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
#property indicator_color1  clrLimeGreen,clrPaleVioletRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
#property indicator_label2  "T3 velocity"
#property indicator_type2   DRAW_COLOR_LINE
#property indicator_color2  clrLimeGreen,clrPaleVioletRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  3

enum enPrices
  {
   pr_close,      // Close
   pr_open,       // Open
   pr_high,       // High
   pr_low,        // Low
   pr_median,     // Median
   pr_typical,    // Typical
   pr_weighted,   // Weighted
   pr_average     // Average (high+low+oprn+close)/4
  };

input double   T3Period    = 14;       // T3 velocity calculation period
input double   T3Hot       = 1.0;      // T3 hot value
input bool     T3Original  = false;    // T3 original Tillson calculation?
input enPrices Price       = pr_close; // Price to use

input bool Alerts=true; // Выдавать алерт на экран
input bool Mail=true; // Посылать сообщение
input bool Push=true; // Посылать ПУШ на телефон
input int shift=1; // На каком баре считать сигнал 0 — на текущем 1 — на

datetime t=0;

double vel[];
double velh[];
double colorBuffer[];
double colorBufferh[];

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   SetIndexBuffer(0,velh,INDICATOR_DATA);
   SetIndexBuffer(1,colorBufferh,INDICATOR_COLOR_INDEX);
   SetIndexBuffer(2,vel,INDICATOR_DATA);
   SetIndexBuffer(3,colorBuffer,INDICATOR_COLOR_INDEX);
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime& time[],
                const double& open[],
                const double& high[],
                const double& low[],
                const double& close[],
                const long& tick_volume[],
                const long& volume[],
                const int& spread[])
  {

   for(int i=(int)MathMax(prev_calculated-1,0); i<rates_total; i++)
     {
      double price = getPrice(Price,open,close,high,low,i,rates_total);
      vel[i]  = iT3(price,T3Period,T3Hot,T3Original,i,rates_total,0)-iT3(price,T3Period,T3Hot/2.0,T3Original,i,rates_total,1);
      velh[i] = vel[i];
      if(i>0)
        {
         colorBuffer[i]  = colorBuffer[i-1];
         colorBufferh[i] = colorBufferh[i-1];
         if(vel[i] > vel[i-1])
            colorBuffer[i] = 0;
         if(vel[i] < vel[i-1])
            colorBuffer[i] = 1;
         if(vel[i] > 0)
            colorBufferh[i]= 0;
         if(vel[i] < 0)
            colorBufferh[i]= 1;
        }
     }

   ArraySetAsSeries(velh,true);

   if(t!=iTime(NULL,0,0))
     {
      if(Alerts)
        {
         if(velh[shift]>velh[shift+1] && velh[shift+1]<velh[shift+2])
            Alert(_Symbol+" Buy!");
         if(velh[shift]<velh[shift+1] && velh[shift+1]>velh[shift+2])
            Alert(_Symbol+" Sell!");
        }

      if(Mail)
        {
         if(velh[shift]>velh[shift+1] && velh[shift+1]<velh[shift+2])
            SendMail("Signal",_Symbol+" Buy!");
         if(velh[shift]<velh[shift+1] && velh[shift+1]>velh[shift+2])
            SendMail("Signal",_Symbol+" Sell!");
        }

      if(Push)
        {
         if(velh[shift]>velh[shift+1] && velh[shift+1]<velh[shift+2])
            SendNotification(_Symbol+" Buy!");
         if(velh[shift]<velh[shift+1] && velh[shift+1]>velh[shift+2])
            SendNotification(_Symbol+" Sell!");
        }
      t=iTime(NULL,0,0);
     }

   Comment("\n Ind1: ",NormalizeDouble(velh[shift],_Digits),
           "\n Ind2: ",NormalizeDouble(velh[shift+1],_Digits));

   return(rates_total);
  }
//------------------------------------------------------------------
//
//------------------------------------------------------------------

double workT3[][12];
double workT3Coeffs[][12];
#define _period 0
#define _c1     1
#define _c2     2
#define _c3     3
#define _c4     4
#define _alpha  5

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double iT3(double price, double period, double hot, bool original, int r, int bars, int instanceNo=0)
  {
   if(ArrayRange(workT3,0) != bars)
      ArrayResize(workT3,bars);
   if(ArrayRange(workT3Coeffs,0) < (instanceNo+1))
      ArrayResize(workT3Coeffs,instanceNo+1);

   if(workT3Coeffs[instanceNo][_period] != period)
     {
      workT3Coeffs[instanceNo][_period] = period;
      double a = hot;
      workT3Coeffs[instanceNo][_c1] = -a*a*a;
      workT3Coeffs[instanceNo][_c2] = 3*a*a+3*a*a*a;
      workT3Coeffs[instanceNo][_c3] = -6*a*a-3*a-3*a*a*a;
      workT3Coeffs[instanceNo][_c4] = 1+3*a+a*a*a+3*a*a;
      if(original)
         workT3Coeffs[instanceNo][_alpha] = 2.0/(1.0 + period);
      else
         workT3Coeffs[instanceNo][_alpha] = 2.0/(2.0 + (period-1.0)/2.0);
     }

   int buffer = instanceNo*6;
   if(r == 0)
     {
      workT3[r][0+buffer] = price;
      workT3[r][1+buffer] = price;
      workT3[r][2+buffer] = price;
      workT3[r][3+buffer] = price;
      workT3[r][4+buffer] = price;
      workT3[r][5+buffer] = price;
     }
   else
     {
      workT3[r][0+buffer] = workT3[r-1][0+buffer]+workT3Coeffs[instanceNo][_alpha]*(price              -workT3[r-1][0+buffer]);
      workT3[r][1+buffer] = workT3[r-1][1+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][0+buffer]-workT3[r-1][1+buffer]);
      workT3[r][2+buffer] = workT3[r-1][2+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][1+buffer]-workT3[r-1][2+buffer]);
      workT3[r][3+buffer] = workT3[r-1][3+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][2+buffer]-workT3[r-1][3+buffer]);
      workT3[r][4+buffer] = workT3[r-1][4+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][3+buffer]-workT3[r-1][4+buffer]);
      workT3[r][5+buffer] = workT3[r-1][5+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][4+buffer]-workT3[r-1][5+buffer]);
     }

   return(workT3Coeffs[instanceNo][_c1]*workT3[r][5+buffer] +
          workT3Coeffs[instanceNo][_c2]*workT3[r][4+buffer] +
          workT3Coeffs[instanceNo][_c3]*workT3[r][3+buffer] +
          workT3Coeffs[instanceNo][_c4]*workT3[r][2+buffer]);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double getPrice(enPrices price, const double& open[], const double& close[], const double& high[], const double& low[], int i, int bars)
  {
   switch(price)
     {
      case pr_close:
         return(close[i]);
      case pr_open:
         return(open[i]);
      case pr_high:
         return(high[i]);
      case pr_low:
         return(low[i]);
      case pr_median:
         return((high[i]+low[i])/2.0);
      case pr_typical:
         return((high[i]+low[i]+close[i])/3.0);
      case pr_weighted:
         return((high[i]+low[i]+close[i]+close[i])/4.0);
      case pr_average:
         return((high[i]+low[i]+close[i]+open[i])/4.0);
     }
   return(0);
  }
//+------------------------------------------------------------------+