//+------------------------------------------------------------------+
//|                                                         UpDn.mq4 |
//|                                              Copyright 2022, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2022, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // торговый объем ордера
extern double Risk       = 1;        // риск
extern double Procent    = 2;        // язь в процентах
extern double Profit     = 10;       // язь в рублях
extern double BProfit    = 10;       // язь в рублях buy
extern double SProfit    = 10;       // язь в рублях sell

extern int StopLoss      = 0;        // лось
extern int TakeProfit    = 0;        // язь
extern int CloseTime     = 0;        // время закрытия в минутах

extern int MAPer         = 44;       // период МА
extern int Count         = 22;       // число поз
extern int Step          = 333;      // шаг
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

extern string Comm       = "Up&Dn";  // коммент

double p=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   p=Bid;
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;
   datetime expiration=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,_Digits),Slip,sl,tp,Comm,Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(Risk>0)
      lot=NormalizeDouble(AccountEquity()*Risk/100000,2);

   return(lot);
  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Время открытия позиции                                           |
//+------------------------------------------------------------------+
datetime TimeOrderOpen()
  {
   datetime tm=0;
   for(int i=0; i<OrdersTotal(); i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
              {
               tm=OrderOpenTime();
               break;
              }
           }
        }
     }
   return(tm);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Pro()
  {
   double pro=(AccountEquity()-AccountBalance())/AccountBalance()*100;//(1100-1000)/1000
   return(pro);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   bool buy=1;
   bool sell=1;
   double ma=iMA(NULL,0,MAPer,0,1,0,0);
   int delta=int(TimeCurrent()-TimeOrderOpen());

   if(Pro()>Procent && Procent>0)
      CloseAll();

   if(AllProfit()>Profit && Profit>0)
      CloseAll();

   if(AllProfit(0)>BProfit && BProfit>0)
      CloseAll(0);

   if(AllProfit(1)>SProfit && SProfit>0)
      CloseAll(1);

   if(delta>CloseTime*60 && CloseTime>0)
      CloseAll();

   if(CountTrades()<Count)
     {
      buy=Bid-p>Step*_Point && Bid>ma;
      sell=p-Bid>Step*_Point && Bid<ma;

      if(buy)
        {
         PutOrder(0,Ask);
         p=Bid;
        }

      if(sell)
        {
         PutOrder(1,Bid);
         p=Bid;
        }
     }

   Comment("\n Lots: ",Lot(),
           "\n Trades: ",CountTrades(),
           "\n Procent: ",Pro(),
           "\n Profit: ",AllProfit(),
           "\n Time: ",TimeOrderOpen(),
           "\n Time Delta: ",int(TimeCurrent()-TimeOrderOpen()));
  }
//+------------------------------------------------------------------+