Opentraders - это независимое сообщество, создаваемое трейдерами и для трейдеров. Присоединяйтесь, нам по пути!

Войти
Регистрация

	zanoza Уровень 9

Подробнее на моей странице...

Группа "Стол заказов MQL"

Рейтинг 2146

_

UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html

Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно

Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5

Свыше 4000 заказов уже выполнено бесплатно!

Перед заказом прочитайте Правила работы Стола заказов

СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)

Подробнее на странице группы...

Доработка советника Wave-Zone-Trading

Стол заказов MQL

Добрый день, многоуважаемые гуру кода!
Пишу заявку с надеждой доработать советник. Потенциал у него очень не плохой (уже есть приемлемые результаты по тестам).
Идея в следующем:
Советник www.opentraders.ru/downloads/download/3459/ по заказу zakaz.opentraders.ru/98762.html
Убрать из советника индикатор Arrow Micro и добавить индикатор TARGET BANDS, после чего останется в работе два индикатора: Sniper Scalp_SMF и TARGET BANDS.
Принцип открытия позиции:
Появляется сигнал от Sniper Scalp_SMF; цена находится вне канала TARGET BANDS.

Далее принцип работы остается таким же:
Закрытие по тейку, лосу, либо получению противоположного сигнала от Sniper Scalp_SMF (Тейк по выбору, как и есть), ну и само собой остается усреднение.
Архив с необходимыми индикаторами:

Dlya korrektirovki.zip (35 Kb)
На всякий случай советник (что бы не искать):

Usrednitel.zip (2 Kb)
Если не получится добавить канальный индикатор, просто оставить один индикатор Sniper Scalp_SMF. Но очень бы хотелось добавить канал.
С уважением и хорошего дня)))

разное

0
Просмотров: 2072
8 декабря 2022, 18:40
zanoza

Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ

Предыдущая запись в группе Доработка заказа http://zakaz.opentraders.ru/54973.html	Следующая запись в группе Советник zoloto2 (дополнение)
08 декабря 2022	08 декабря 2022

Брокер для ваших роботов, 15 лет на рынке

на 20-е

35 AM2 Сообщений: 16266 - Андрей

8 декабря 2022, 19:54
↓

9 zanoza Автор Сообщений: 44

8 декабря 2022, 19:56
↓

Андрею в помощь, вот держи, на Sniper Scalp_SMF, до канала я «не дорос ещё», у меня работает, и в тесте, и на демо(скрины).., в тесте — сам…

//+------------------------------------------------------------------+
//|                                  Usrednitel_Sniper Scalp_SMF.mq4 |
//|                                              Copyright 2022, AM2 |
//|                                     https://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2022, AM2"
#property link      "https://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 2;        // умножение лота
extern double MaxLot     = 99999;    // максимальный лот

extern int StopLoss      = 0;        // лось
extern int TakeProfit    = 0;        // язь

extern int Step          = 500;      // шаг
extern int Count         = 100;      // число поз
extern int Slip          = 30;       // реквот
extern int CloseSig      = 1;        // 1-закрытие по сигналу
extern int Shift         = 1;        // бар индикатора
extern int Magic         = 1;        // магик

extern string Comm       = "Wave";

extern string IndName2   = "Sniper Scalp_SMF";

extern double Period1    = 0;
extern double Period2    = 0;
extern double Period3    = 24;

extern double DevStep1   = 0;
extern double DevStep2   = 0;
extern double DevStep3   = 3.8;

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(type),NormalizeDouble(price,_Digits),Slip,sl,tp,Comm,Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool TimeSession(int aStartHour,int aStartMinute,int aStopHour,int aStopMinute,datetime aTimeCur)
  {
//--- время начала сессии
   int StartTime=3600*aStartHour+60*aStartMinute;
//--- время окончания сессии
   int StopTime=3600*aStopHour+60*aStopMinute;
//--- текущее время в секундах от начала дня
   aTimeCur=aTimeCur%86400;
   if(StopTime<StartTime)
     {
      //--- переход через полночь
      if(aTimeCur>=StartTime || aTimeCur<StopTime)
        {
         return(true);
        }
     }
   else
     {
      //--- внутри одного дня
      if(aTimeCur>=StartTime && aTimeCur<StopTime)
        {
         return(true);
        }
     }
   return(false);
  }

12 mishelbb Сообщений: 220 - mishelbb

9 декабря 2022, 10:13
↑
↓

…

//+------------------------------------------------------------------+
//| Подсчет позиций                                                  |
//+------------------------------------------------------------------+
int CountTrades(int ot=-1)
  {
   int count=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
               count++;
            if(OrderType()==1 && (ot==1 || ot==-1))
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot(int type)
  {
   double lot=Lots;

   if(CountTrades(type)>0)
     {
      lot=NormalizeDouble(Lots*MathPow(KLot,CountTrades(type)),2);
     }

   if(lot>MaxLot)
      lot=Lots;

   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl=1;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int FindOrderType()
  {
   int type=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            type=OrderType();
            break;
           }
        }
     }
   return(type);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double FindLastBuyPrice()
  {
   double p=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderType()==OP_BUY && OrderMagicNumber()==Magic)
           {
            p=OrderOpenPrice();
            break;
           }
        }
     }
   return(p);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double FindLastSellPrice()
  {
   double p=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderType()==OP_SELL && OrderMagicNumber()==Magic)
           {
            p=OrderOpenPrice();
            break;
           }
        }
     }
   return(p);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ModifyOrders()
  {
   bool mod=1;
   double allb=0,alls=0;
   double countb=0,counts=0,tp=0,sl=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0)
              {
               allb+=OrderOpenPrice()*OrderLots();
               countb+=OrderLots();
              }

            if(OrderType()==1)
              {
               alls+=OrderOpenPrice()*OrderLots();
               counts+=OrderLots();
              }
           }
        }
     }
   if(countb>0)
      allb=NormalizeDouble(allb/countb,_Digits);
   if(counts>0)
      alls=NormalizeDouble(alls/counts,_Digits);

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0)
              {
               if(TakeProfit>0)
                  tp=NormalizeDouble(allb+TakeProfit*_Point,_Digits);
               if(StopLoss>0)
                  sl=NormalizeDouble(allb-StopLoss*_Point,_Digits);
               if(OrderTakeProfit()!=tp || OrderStopLoss()!=sl)
                  mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
              }
            else
               if(OrderType()==1)
                 {
                  if(TakeProfit>0)
                     tp=NormalizeDouble(alls-TakeProfit*_Point,_Digits);
                  if(StopLoss>0)
                     sl=NormalizeDouble(alls+StopLoss*_Point,_Digits);
                  if(OrderTakeProfit()!=tp || OrderStopLoss()!=sl)
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
                 }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double lim=iCustom(NULL,0,IndName2,5,Shift);
   double tom=iCustom(NULL,0,IndName2,4,Shift);

   bool buy = lim!=EMPTY_VALUE && tom>0;
   bool sell = tom!=EMPTY_VALUE && lim>0;

   if(CountTrades()<1)
     {
      if(buy)
        {
         PutOrder(0,Ask);
        }
      if(sell)
        {
         PutOrder(1,Bid);
        }
     }

   if(CountTrades()<Count)
     {
      if(FindOrderType()==0 && FindLastBuyPrice()-Ask>Step*_Point)
        {
         PutOrder(0,Ask);
         ModifyOrders();
        }

      if(FindOrderType()==1 && Bid-FindLastSellPrice()>Step*_Point)
        {
         PutOrder(1,Bid);
         ModifyOrders();
        }
     }

   if(CloseSig>0)
     {
      if(sell)
        {
         CloseAll(0);
        }
      if(buy)
        {
         CloseAll(1);
        }
     }

   Comment("\n lim: ",lim,
           "\n tom: ",tom);
  }
//+------------------------------------------------------------------+

12 mishelbb Сообщений: 220 - mishelbb

9 декабря 2022, 10:16
↑
↓

Спасибо большое. Попробую.

9 zanoza Автор Сообщений: 44

9 декабря 2022, 11:05
↑
↓

Интересно.

18 Boris54 Сообщений: 810 - ПенSионер

9 декабря 2022, 06:57
↓

поменял индикатор: www.opentraders.ru/downloads/3469/

35 AM2 Сообщений: 16266 - Андрей

10 декабря 2022, 09:49
↓

Благодарю

9 zanoza Автор Сообщений: 44

11 декабря 2022, 19:37
↑
↓

Андрей, здравствуйте. В процессе тестов выявил, что советник немного не корректно закрывает позиции. Закрытие должно происходить только по обратному сигналу от Sniper Scalp_SMF.
Т.е. открытие по двум индикаторам, а закрытие по одному.
Может я ТЗ не правильно сформулировал *stesnitelno*

Исправьте пожалуйста, буду очень признателен)))

9 zanoza Автор Сообщений: 44

13 декабря 2022, 23:52
↑
↓

поставь в тестор и посмотри после сделки где коснется цена противоположной линии канала и останови тестор