Помогите решить проблему с отрисовкой горизонтальной линии

Стол заказов MQL

Андрей, приветствую. Есть функция вывода уровня цены Stop Out


//----------------------------------------------------------------------------------------------
double d_shift_3,u_shift_3=0;
if ( lots > 0) // lots — сумма всех лотов сетки
{
d_shift_3 = AccountEquity() / (MarketInfo(Symbol(), MODE_TICKVALUE) * lots);
if (GetLot(0))
{
u_shift_3 = Bid —  d_shift_3*Point; // уровень полного слива сетки buy
}
if (GetLot(1))
{
u_shift_3 = Ask + d_shift_3*Point; // уровень полного слива сетки sell
}
}
else u_shift_3 = 0.0;
SM(«StopOut price: » + DoubleToString(u_shift_3,Digits)); // вывод на график
//------------------------------------------------------------------------------------------------

в результате получаем цену (u_shift_3), которую выводим на график.
Эта конструкция работает! Выводит цену SO, изменяет ее в случае накопления ордеров сетки (сетка строится только в BUY или SELL). В общем, тут всё норм, в плане работоспособности. Я не уверен, что формула правильная (может кто поправит если что), но где-то очень близко подходит..)

Вопрос в следующем:
Как нарисовать горизонтальную линию параметра u_shift_3?

Я пробовал так:


if (u_shift_3 >0)
{
ObjectCreate(«SO_Line»,OBJ_HLINE,0,0,u_shift_3);
ObjectSet(«SO_Line»,OBJPROP_COLOR,Red);
ObjectSet(«SO_Line»,OBJPROP_STYLE,0);
ObjectSet(«SO_Line»,OBJPROP_WIDTH,2);
ObjectSet(«SO_Line»,OBJPROP_BACK,true);
}
else
ObjectCreate(«SO_Line»,0,0,0,u_shift_3);

Вообще ничего не выводится, не рисуется линия(((
Уже два дня мучаю гугл с этими линиями… Никак…
Вместо u_shift_3 подставлял другие значения, чтобы проверить, может конкретно в u_shift_3 проблема. Ставил Ask — линия рисуется при запуске советника, но не перемещается за ценой…
В общем, я в полном тупике…

разное

0
Просмотров: 1228
19 сентября 2023, 17:34
FEEX

Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ

Предыдущая запись в группе Стоповый усреднитель на основе трех свечей (БЫКИ и МЕДВЕДИ).	Следующая запись в группе изменить советник
19 сентября 2023	20 сентября 2023

Брокер для ваших роботов, 15 лет на рынке

посмотрю сегодня

35 AM2 Сообщений: 16265 - Андрей

19 сентября 2023, 18:06
↓

полный код скиньте. с функцией гет лот

35 AM2 Сообщений: 16265 - Андрей

19 сентября 2023, 18:10
↓

полный код 1000+строк)))
функция гет лот:


//+------------------------------------------------------------------+
//|Возвращает сумму лота открытых ордеров                            |
//+------------------------------------------------------------------+
double GetLot(int type)
  {
   double sum_lo=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {        
          if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {            
             if(OrderType()==type)
               {
                sum_lo+=OrderLots();
               }
              
           }
        }
     }
   return(sum_lo);
  }
//+------------------------------------------------------------------+

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 18:27
↑
↓

надо все смотреть. обрывки кода здесь не помогут

35 AM2 Сообщений: 16265 - Андрей

19 сентября 2023, 18:37
↓

там больше 1000 строк — оно сюда даже не влезет, плюс еще графика bmp…
По сути, для вывода цены SO там больше ничего и не задействовано. Всё, что участвует, я скинул. Вопрос только в отрисовки линии параметра u_shift_3 — цена стоп аута. )
И некоторые фишки не хотелось бы в открытый доступ выкладывать…
Редактирован: 19 сентября 2023, 18:52

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 18:51
↓

я так то за чужой код редко берусь а с обрывками тем более

35 AM2 Сообщений: 16265 - Андрей

19 сентября 2023, 19:01
↓

Я помню)) Ладно, буду дальше думать, как заставить линию нарисоваться)

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 19:19
↓


if(u_shift_3!=0)
  {
   if(ObjectFind("SO_Line")!=-1)
     {
      ObjectCreate(0,"SO_Line",OBJ_HLINE,0,0,u_shift_3)
      ObjectSet(0,"SO_Line",OBJPROP_COLOR,Red);
      ObjectSet(0,"SO_Line",OBJPROP_STYLE,0);
      ObjectSet(0,"SO_Line",OBJPROP_WIDTH,2);
      ObjectSet(0,"SO_Line",OBJPROP_BACK,true);
     }
   else
     ObjectMove(0,"SO_Line",0,0,u_shift_3);
  }

14 verta81 Сообщений: 390

19 сентября 2023, 22:09
↓

Благодарю за вариант! Вы только не поставили ";" в конце ObjectCreate(0,«SO_Line»,OBJ_HLINE,0,0,u_shift_3)
запарился искать ошибку)))
Но этот вариант тоже не выдает линию, или я что-то не то делаю…

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 23:29
↑
↓

u_shift_3 чему равен? проверяли?

14 verta81 Сообщений: 390

19 сентября 2023, 23:32
↓

Если нет открытых ордеров, то 0, если есть ордера, то выводится цена стоп аута
это сумма лотов всех открытых ордеров.

<code>
double lots=0;    
   if (GetLot(0) > 0)
          {
           lots=GetLot(0);                      
          }
   if (GetLot(1) > 0)
          {
           lots=GetLot(1);                      
          }  
   SM("All volume trade now    : " + DoubleToString(lots,2) +" lots");
</code>

а это формула расчета цены стоп аута с выводом на график самой цены:

<code>
//---------------------------------------------------------------------------------------------------  
    double   d_shift_3,u_shift_3=0; 
    if ( lots > 0) // lots - сумма всех лотов сетки
       {
         d_shift_3 = AccountEquity() / (MarketInfo(Symbol(), MODE_TICKVALUE) * lots); 
         if (GetLot(0))
           {
             u_shift_3 = Bid - d_shift_3*Point;  // уровень полного слива сетки buy
           }
         if (GetLot(1))
           { 
             u_shift_3 = Ask + d_shift_3*Point;  // уровень полного слива сетки sell
           }
       }                     
         else u_shift_3 = 0.0; 
//--------------------------------------------
</code>

В советнике, который я сюда скинул (код в двух частях), там это все реализовано и если две части кода соединить, то и на графике всё видно будет. В комментах выводится значение.

Сразу предупреждаю, я в этом плохо разбираюсь… В сети не нашел вообще подобного, такое ощущение что именно расчет ЦЕНЫ стоп аута вообще никого не интересует, всех удовлетворяет процент, который и нафиг никому не нужен… В общем, пришлось самому мудрить, и я не уверен, что формула верна, но что-то очень похожее на првду в ней есть)))
Редактирован: 19 сентября 2023, 23:51

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 23:46
↑
↓

Андрей, я нашел Ваш советник, приспособил туда функцию,, которую выше описывал, сделал вывод на график значения цены стоп аута. Там еще линию безубытка добавил (тоже Ваш код). В общем, посмотрите, пожалуйста, как можно сделать линию цены стоп аута.
Чуть не забыл!!! Не могли бы Вы сделать там же открытие ордеров на нулевом баре, согласно шага, сейчас ордера открываются на новой свече.


//+------------------------------------------------------------------+
//|                                                       Zoloto.mq4 |
//|                                              Copyright 2021, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Risk       = 2;        // риск (если = 0, off)
extern double Lots       = 0.1;      // торговый объем ордера
extern double MaxLot     = 5;        // максимальный торговый объем
extern double KLot       = 1.3;      // увеличение лота

extern int StopLoss      = 0;        // лось
extern int TakeProfit    = 0;        // язь
extern int TrailingStop  = 50;       // трал

extern int MA            = 108;      // период МА
extern int Step          = 200;      // шаг
extern int Count         = 20;       // Max ордеров серии
extern int Slip          = 30;       // реквот

extern int StartHour     = 1;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли

extern int Magic         = 123;      // магик
extern bool Express      = 1;        // поза сразу

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,_Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades(int type=-1)
  {
   int count=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|   обычный трал                                                               |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   double all=0,count=0,sl=0;

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()<2)
              {
               all+=OrderOpenPrice()*OrderLots();
               count+=OrderLots();
              }
           }
        }
     }

   if(count>0) all=NormalizeDouble(all/count,Digits);

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-all>TrailingStop*_Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*_Point)
                    {
                     sl=NormalizeDouble(Bid-TrailingStop*_Point,Digits);
                     if(OrderStopLoss()!=sl) mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,OrderTakeProfit(),0,Yellow);
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(all-Ask>TrailingStop*_Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*_Point)) || (OrderStopLoss()==0))
                    {
                     sl=NormalizeDouble(Bid+TrailingStop*_Point,Digits);
                     if(OrderStopLoss()!=sl) mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,OrderTakeProfit(),0,Yellow);
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+    
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ModifyOrders()
  {
   double allb=0,alls=0;
   double countb=0,counts=0,tp=0,sl=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0)
              {
               allb+=OrderOpenPrice()*OrderLots();
               countb+=OrderLots();
              }

            if(OrderType()==1)
              {
               alls+=OrderOpenPrice()*OrderLots();
               counts+=OrderLots();
              }
           }
        }
     }
   if(countb>0)
      allb=NormalizeDouble(allb/countb,_Digits);
   if(counts>0)
      alls=NormalizeDouble(alls/counts,_Digits);

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==OP_BUY)
              {
               if(TakeProfit>0)
                  tp=NormalizeDouble(allb+TakeProfit*_Point,_Digits);
               if(StopLoss>0)
                  sl=NormalizeDouble(allb-StopLoss*_Point,_Digits);
               if(OrderTakeProfit()!=tp || OrderStopLoss()!=sl)
                  bool mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
              }
            else
               if(OrderType()==OP_SELL)
                 {
                  if(TakeProfit>0)
                     tp=NormalizeDouble(alls-TakeProfit*_Point,_Digits);
                  if(StopLoss>0)
                     sl=NormalizeDouble(alls+StopLoss*_Point,_Digits);
                  if(OrderTakeProfit()!=tp || OrderStopLoss()!=sl)
                     bool mod=OrderModify(OrderTicket(),OrderOpenPrice(),sl,tp,0,Yellow);
                 }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool TimeSession(int aStartHour,int aStartMinute,int aStopHour,int aStopMinute,datetime aTimeCur)
  {
//--- время начала сессии
   int StartTime=3600*aStartHour+60*aStartMinute;
//--- время окончания сессии
   int StopTime=3600*aStopHour+60*aStopMinute;
//--- текущее время в секундах от начала дня
   aTimeCur=aTimeCur%86400;
   if(StopTime<StartTime)
     {
      //--- переход через полночь
      if(aTimeCur>=StartTime || aTimeCur<StopTime)
        {
         return(true);
        }
     }
   else
     {
      //--- внутри одного дня
      if(aTimeCur>=StartTime && aTimeCur<StopTime)
        {
         return(true);
        }
     }
   return(false);
  }    
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(Risk>0)
      lot=NormalizeDouble(AccountBalance()*Risk/100000,2);

   if(CountTrades()>0)
      lot=NormalizeDouble(lot*MathPow(KLot,CountTrades()),2);
   if(lot>MaxLot)
      lot=Lots;
   return(lot);
  }

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 23:36
↓

продолжение кода (окончание), весь не влез)


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int FindOrderType()
  {
   int oticket,ticketNumber=0,type=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            oticket=OrderTicket();
            if(oticket>ticketNumber)
              {
               ticketNumber=oticket;
               type=OrderType();
              }
           }
        }
     }
   return(type);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double FindLastBuyPrice()
  {
   int oticket,ticketNumber=0;
   double oprice=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderType()==OP_BUY)
           {
            oticket=OrderTicket();
            if(oticket>ticketNumber)
              {
               ticketNumber=oticket;
               oprice=OrderOpenPrice();
              }
           }
        }
     }
   return(oprice);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double FindLastSellPrice()
  {
   int oticket,ticketNumber=0;
   double oprice=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderType()==OP_SELL)
           {
            oticket=OrderTicket();
            if(oticket>ticketNumber)
              {
               ticketNumber=oticket;
               oprice=OrderOpenPrice();
              }
           }
        }
     }
   return(oprice);
  }
//+------------------------------------------------------------------+
//|Возвращает сумму лота открытых ордеров                            |
//+------------------------------------------------------------------+
double GetLot(int type)
  {
   double sum_lo=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {        
          if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {            
             if(OrderType()==type)
               {
                sum_lo+=OrderLots();
               }
              
           }
        }
     }
   return(sum_lo);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double BULine(int type)
  {
   double all=0, count=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type)
              {
               all+=OrderOpenPrice()*OrderLots();
               count+=OrderLots();
              }
           }
        }
     }
   if(count>0)
      all=NormalizeDouble(all/count,_Digits);
   return(all);
  }
//+------------------------------------------------------------------+
//| Горизонтальная линия                                             |
//+------------------------------------------------------------------+
void PutHLine(string name,double p,color clr)
  {
   ObjectDelete(0,name);
   ObjectCreate(0,name,OBJ_HLINE,0,0,p);
//--- установим цвет линии
   ObjectSetInteger(0,name,OBJPROP_COLOR,clr);
//--- установим толщину линии
   ObjectSetInteger(0,name,OBJPROP_WIDTH,1);
  }    
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double ma = iMA(NULL,0,MA,0,0,0,0);

   if(TrailingStop>0)
      Trailing();

//+-------------------express-----------------------------------------------+
   if(CountTrades()<1 && Express)
     {
      if(Bid>ma)
        {
         PutOrder(0,Ask);
         ModifyOrders();
        }
      if(Bid<ma)
        {
         PutOrder(1,Bid);
         ModifyOrders();
        }
     }
//+--------------------express----------------------------------------------+

   if(t!=Time[0])
     {
     
      if(CountTrades()<1 && TimeSession(StartHour,StartMin,EndHour,EndMin,TimeCurrent()))
      //if(CountTrades()<1)
        {
         if(Bid>ma)
           {
            PutOrder(0,Ask);
            ModifyOrders();
           }
         if(Bid<ma)
           {
            PutOrder(1,Bid);
            ModifyOrders();
           }
        }

      if(CountTrades(0)<Count &&
      ((FindOrderType()==0 && CountTrades(0)==1)||CountTrades(0)>1) && CountTrades(1)<2 && 
      (FindLastBuyPrice()-Ask)/_Point>=Step)                                 
        {
         PutOrder(0,Ask);
         ModifyOrders();
        }
     if(CountTrades(1)<Count &&
      ((FindOrderType()==1 && CountTrades(1)==1)||CountTrades(1)>1) && CountTrades(0)<2 && 
      (Bid-FindLastSellPrice())/_Point>=Step)                               
        {
         PutOrder(1,Bid);
         ModifyOrders();
        }

     t=Time[0];
     }
  //-----------------------------------------------------
   double lots=0;    
   if (GetLot(0) > 0)
          {
           lots=GetLot(0);                      
          }
   if (GetLot(1) > 0)
          {
           lots=GetLot(1);                      
          } 
  //-----------------------------------------------------
     
     double   d_shift_3,u_shift_3=0; 
    if ( lots > 0) // lots - сумма всех лотов сетки
       {
         d_shift_3 = AccountEquity() / (MarketInfo(Symbol(), MODE_TICKVALUE) * lots); 
         if (GetLot(0))
           {
             u_shift_3 = Bid - d_shift_3*Point;  // уровень полного слива сетки buy
           }
         if (GetLot(1))
           { 
             u_shift_3 = Ask + d_shift_3*Point;  // уровень полного слива сетки sell
           }
       }                     
         else u_shift_3 = 0.0;
         
   PutHLine("Buy BU Line",BULine(0),Lime);
   PutHLine("Sell BU Line",BULine(1),OrangeRed);   
         

   Comment("\n Balance  = ",DoubleToString(AccountBalance(),2), " ",  AccountCurrency(),
           "\n Profit  = ",DoubleToString (AccountProfit(),2), " ",  AccountCurrency(),
           "\n Next Lot  = ",Lot(),
           "\n StopOut price = ",DoubleToString(u_shift_3,Digits),
           "\n All volume trade now = ",DoubleToString(lots,2),           
           "\n Trades = ",CountTrades());        
           
  }
//+------------------------------------------------------------------+

11 FEEX Автор Сообщений: 361 - Владимир

19 сентября 2023, 23:38
↓


   if(u_shift_3!=0)
  {
   if(ObjectFind("SO_Line")==-1)
     {
      ObjectCreate(0,"SO_Line",OBJ_HLINE,0,0,u_shift_3);
      ObjectSetInteger(0,"SO_Line",OBJPROP_COLOR,Red);
      ObjectSetInteger(0,"SO_Line",OBJPROP_STYLE,0);
      ObjectSetInteger(0,"SO_Line",OBJPROP_WIDTH,2);
      ObjectSetInteger(0,"SO_Line",OBJPROP_BACK,true);
     }
   else
     ObjectMove(0,"SO_Line",0,0,u_shift_3);
  }

14 verta81 Сообщений: 390

19 сентября 2023, 23:40
↓

Дай бог Вам здоровья!!))) Работает)))

11 FEEX Автор Сообщений: 361 - Владимир

20 сентября 2023, 00:00
↑
↓

Формула немного не точная, слив происходит чуть раньше. Может цена стоп аута как-то иначе расчитывается… У меня мозгов хватило пока только на такой вариант. Может кто-то сможет придумать вариант поточнее?
Просто реально в инете этого нет вообще! По крайней мере за два дня я не нашел ничего похожего…

11 FEEX Автор Сообщений: 361 - Владимир

20 сентября 2023, 00:23
↓

это очень полезный индикатор, поделитесь или все останется за кадром? Я хотел бы простой прос то линия и все

6 Ramboo Сообщений: 92 - Ram

20 сентября 2023, 12:30
↑
↓

Есть такой индикатор i-UrovenZero, в нем реализована функция стоп-аута. В поисковике без труда найдете.

14 OSS5 Сообщений: 148

20 сентября 2023, 06:24
↓

все хорошо но много лишнего в нем нагромождено

6 Ramboo Сообщений: 92 - Ram

20 сентября 2023, 12:30
↑
↓

я оттуда и брал схему… но там черт ногу сломит…
я попробовал вытащить суть расчета, но походу там значение lots это не сумма всех лотов открытых ордеров, но тогда что??
Кто может написать расчет цены стоп аута с отрисовкой линии этой цены в советнике Андрея, который я выше скинул (в двух постах)?

P.S. Кстати, я проверил — индикатор i-UrovenZero и моя функция показывают ОДИНАКОВОЕ значение цены стоп аута, т.е. логику из индюка я понял правильно…

Но она НЕ точная!!! Слив происходит раньше цены, которую показывает индюк, на 10-15 пунктов (4-х знак). Выше скрин есть, там слив случился 14 пунктов не дойдя до линии слива — которая рисуется по формуле из индюка.
Редактирован: 20 сентября 2023, 16:18

11 FEEX Автор Сообщений: 361 - Владимир

20 сентября 2023, 12:55
↑
↓

Возвращает значение уровня, по которому определяется состояние Stop Out.

int  AccountStopoutLevel();

Не вариант?

14 verta81 Сообщений: 390

22 сентября 2023, 12:44
↓

это проценты)))
нужна ЦЕНА уровня SO
с каждым новым открытым ордером эта цена изменяется.
а AccountStopoutLevel(); это процент, выданный брокером по конкретному типу счета. Он не меняется)

11 FEEX Автор Сообщений: 361 - Владимир

22 сентября 2023, 13:05
↑
↓

www.mql5.com/ru/market/product/72446?source=External а такую пробовали?

6 Ramboo Сообщений: 92 - Ram

22 сентября 2023, 13:14
↓

Прикольная штука, но нужен открытый код. Он есть?)
И мне не нужен индикатор, мне нужно это реализовать в советнике)
Уже сделали даже) только есть нюансы… Я ниже описал.
Редактирован: 22 сентября 2023, 13:49

11 FEEX Автор Сообщений: 361 - Владимир

22 сентября 2023, 13:48
↑
↓

На одном форуме подсказали — вроде работает теперь правильно.

Но есть проблема: если нет открытых ордеров, то вместо 0.00000 в строке StopOut price там выводится текушая цена, а этого не должно быть!!! Если нет откр. ордеров, там должно быть 0.00000.
Вот как это сделать — я хз…
P.S. Плохо что к посту нельзя файл прикреплять(((

11 FEEX Автор Сообщений: 361 - Владимир

22 сентября 2023, 13:44
↓

на яндекс диск или майл ру облако залейте и скиньте ссылку сюда что получилось то хоть посмотреть? я активно торгую советниками мне тоже интересно. Да не оскудеет рука дающего (с) *lalala*

6 Ramboo Сообщений: 92 - Ram

22 сентября 2023, 13:54
↑
↓

ответил в ЛС 8-)

11 FEEX Автор Сообщений: 361 - Владимир

22 сентября 2023, 15:59
↑
↓

здесь самое простое будет сделать сигнал, когда просадка достигнет допустим 50% от депо

35 AM2 Сообщений: 16265 - Андрей

22 сентября 2023, 19:46
↓

это уже на любителя)) хотя для просадки, наверное, будет достаточно добавить инфу на график: текущая просадка и макс. просадка. Мне интересно было сделать цену, не процент, а именно вычислить цену стопаута и вывести её в инфу на график, плюс линию отрисовать на цене. Если совсем заморочиться, можно еще и цену маржинкола))
Понятно, что сова от этого лучше торговать не начнет, это чисто чтобы было)) Лучше, если оно есть, чем если этого нет)
Редактирован: 22 сентября 2023, 23:18

11 FEEX Автор Сообщений: 361 - Владимир

22 сентября 2023, 23:15
↑
↓

В этой формуле Вы не учли уровень Stop Out:

d_shift_3 = AccountEquity() / (MarketInfo(Symbol(), MODE_TICKVALUE) * lots);

Правильнее будет так:

d_shift_3 = (AccountEquity() - AccountStopoutLevel()) / MarketInfo(Symbol(), MODE_TICKVALUE) * lots;

14 verta81 Сообщений: 390

23 сентября 2023, 00:21
↓

да, точно) просмотрел, спасибо!))) Но этот вопрос уже решили, там уже этот момент учтен)
Редактирован: 23 сентября 2023, 00:42

11 FEEX Автор Сообщений: 361 - Владимир

23 сентября 2023, 00:42
↑
↓

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий

Группа "Стол заказов MQL"

Свыше 4000 заказов уже выполнено бесплатно!

РЕКОМЕНДУЮ

Лучшее от FEEX

Помогите решить проблему с отрисовкой горизонтальной линии

Комментарии (31)

Рейтинг брокеров FOREX

Из недавнего:

	FEEX Владимир Уровень 11

Авторизация

Группа "Стол заказов MQL"

Свыше 4000 заказов уже выполнено бесплатно!

РЕКОМЕНДУЮ

Лучшее от FEEX

Помогите решить проблему с отрисовкой горизонтальной линии

Вставка изображения

СМАЙЛИКИ

Позитив

Негатив

Роли

Еще

Плакаты, знаки

Комментарии (31)

Рейтинг брокеров FOREX

Из недавнего: