<code>
//+------------------------------------------------------------------+
//|                                                     AMAColor.mq4 |
//|                                              Copyright 2014, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2011, AM2"
#property link      "http://www.forexsystems.biz"
#property description "AMA Color simple expert advisor"

#define MAGICMA  20141020
//--- Inputs
input double StopLoss     = 500;
input double TakeProfit   = 500;
input double Delta        = 500;
input double Lots         = 0.1;
//----
extern int Range          = 9;
extern int FastMA         = 2;
extern int SlowMA         = 30;
extern int CountBars      = 200;
extern int filter         = 25;
//----

//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void CheckForOpen()
  {
   int    res;
//--- go trading only for first tiks of new bar
   if(Volume[0]>1) return;
//--- get Moving Average 
   double AMABlue=iCustom(Symbol(),0,"AMAColor",Range,FastMA,SlowMA,CountBars,filter,0,0);
   double AMARed=iCustom(Symbol(),0,"AMAColor",Range,FastMA,SlowMA,CountBars,filter,1,0);
   double sl,tp,dl;
   if(Digits==3||Digits==5) {sl=StopLoss*Point*10;tp=TakeProfit*Point*10;dl=Delta*Point*10;}
   if(Digits==2||Digits==4) {sl=StopLoss*Point;tp=TakeProfit*Point;dl=Delta*Point;}

//--- sell conditions
   if(AMABlue>AMARed && Bid>AMARed+dl)
     {
      res=OrderSend(Symbol(),OP_SELL,Lots,Bid,3,Bid+sl,Bid-tp,"",MAGICMA,0,Red);
      return;
     }
//--- buy conditions
   if(AMARed>AMABlue && Ask<AMABlue-dl)
     {
      res=OrderSend(Symbol(),OP_BUY,Lots,Ask,3,Ask-sl,Ask+tp,"",MAGICMA,0,Blue);
      return;
     }
//---
  }
//+------------------------------------------------------------------+
//| Check for close order conditions                                 |
//+------------------------------------------------------------------+
void CheckForClose()
  {
//--- go trading only for first tiks of new bar
   if(Volume[0]>1) return;
//--- get AMA
   double AMABlue=iCustom(Symbol(),0,"AMAColor",Range,FastMA,SlowMA,CountBars,filter,0,0);
   double AMARed=iCustom(Symbol(),0,"AMAColor",Range,FastMA,SlowMA,CountBars,filter,1,0);
//---
   for(int i=0;i<OrdersTotal();i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false) break;
      if(OrderMagicNumber()!=MAGICMA || OrderSymbol()!=Symbol()) continue;
      //--- check order type 
      if(OrderType()==OP_BUY)
        {
         if(AMABlue>AMARed)
           {
            if(!OrderClose(OrderTicket(),OrderLots(),Bid,3,White))
               Print("OrderClose error ",GetLastError());
           }
         break;
        }
      if(OrderType()==OP_SELL)
        {
         if(AMARed>AMABlue)
           {
            if(!OrderClose(OrderTicket(),OrderLots(),Ask,3,White))
               Print("OrderClose error ",GetLastError());
           }
         break;
        }
     }
//---
  }
//+------------------------------------------------------------------+
//| OnTick function                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- check for history and trading
   if(Bars<100 || IsTradeAllowed()==false)
      return;
//--- calculate open orders by current symbol
   if(OrdersTotal()<1) CheckForOpen();
   else CheckForClose();
//---
  }
//+------------------------------------------------------------------+

</code>