//+------------------------------------------------------------------+
//|                                           Expert_Riverside_v.mq4 |
//|                                                              Oxy |
//|                                   http://oxy.opentraders.ru/bio/ |
//+------------------------------------------------------------------+
#property copyright "Oxy"
#property link      "http://oxy.opentraders.ru/bio/"
#property version   "1.00"
#property strict
//------- Внешние параметры советника -----------------------------------------+
extern int     Ma_Period         = 233;         // Значение МА
extern int     Ma_Level_1        = 150;         // Уровень 1 Ма
extern int     Ma_Level_2        = 890;         // Уровень 2 Ма
extern int     Ma_Level_3        = 1440;        // Уровень 3 Ма
extern int     Ma_Level_4        = 2330;        // Уровень 4 Ма
extern double  Lot_1             = 0.1;         // Лот 1
extern double  Lot_2             = 0.2;         // Лот 2
extern double  Lot_3             = 0.3;         // Лот 3
             
extern int     Slippage          = 30;          // Проскальзывание цены
extern int     MagicNumber       = 567562;      // Идентификатор ордера
//------- Глобальные переменные советника -------------------------------------+
string   Symb;
string   NameInd     = "Indicator_Riverside";
datetime timePrev    = -1;
string   LEVEL2 = "LEVEL2";
string   LEVEL3 = "LEVEL3";
string   LEVEL4 = "LEVEL4";
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   if (!IsTradeAllowed())  { Print("Необходимо разрешить советнику торговать"); return(INIT_FAILED);}  
   if (Period()<PERIOD_M5) { Print("Советник работает не ниже таймфрейма M5!"); return(INIT_FAILED);}
   Symb = Symbol();
   if(Ma_Level_1<=0 || Ma_Level_2<Ma_Level_1 || Ma_Level_3<Ma_Level_2 || Ma_Level_4<Ma_Level_3) 
     { Print("Неправильно выставлены уровни!"); return(INIT_FAILED); } 
   if (Lot_1<MarketInfo(Symbol(), MODE_MINLOT) || Lot_1>MarketInfo(Symbol(), MODE_MAXLOT)) { Print("Неправильно выставлен лот 1!"); return(INIT_FAILED);}
   if (Lot_2<MarketInfo(Symbol(), MODE_MINLOT) || Lot_2>MarketInfo(Symbol(), MODE_MAXLOT)) { Print("Неправильно выставлен лот 2!"); return(INIT_FAILED);}
   if (Lot_3<MarketInfo(Symbol(), MODE_MINLOT) || Lot_3>MarketInfo(Symbol(), MODE_MAXLOT)) { Print("Неправильно выставлен лот 3!"); return(INIT_FAILED);}
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason) { }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   if(timePrev!=Time[1]) {
     double _trRv_H_LV1_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 1, 0);
     double _trRv_H_LV1_1 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 1, 1);
     double _trRv_H_LV1_2 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 1, 2);
     
     double _trRv_H_LV2_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 2, 0);
     double _trRv_H_LV3_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 3, 0);
     double _trRv_H_LV4_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 4, 0);

     double _trRv_L_LV1_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 6, 0);
     double _trRv_L_LV1_1 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 6, 1);
     double _trRv_L_LV1_2 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 6, 2);
     
     double _trRv_L_LV2_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 7, 0);
     double _trRv_L_LV3_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 8, 0);
     double _trRv_L_LV4_0 = iCustom(Symb, 0, NameInd, Ma_Period, Ma_Level_1, Ma_Level_2, Ma_Level_3, Ma_Level_4, 9, 0);
     
     // переносим sl
     if(HaveOpenPos()) {
       int i, ot, k=OrdersTotal(), opP_b, opP_s;
       opP_b = AmountOpenPos(0);
       opP_s = AmountOpenPos(1);
       double sl, tp;
       for (i=k-1; i>=0; i--) {
         if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
           if (OrderSymbol()==Symb && OrderMagicNumber()==MagicNumber) {
             ot=OrderType();
             sl=0; tp=0;
             if(ot==0) {               
               if(opP_b==3) sl = NormalizeDouble(_trRv_L_LV1_0, Digits);
               if(opP_b==2) sl = NormalizeDouble(_trRv_H_LV1_0, Digits);
               if(opP_b==1) sl = NormalizeDouble(_trRv_H_LV2_0, Digits);

               if(OrderStopLoss()!=sl && MathAbs(sl-OrderOpenPrice())>MarketInfo(Symb, MODE_STOPLEVEL)*Point)
                 if(!OrderModify(OrderTicket(), OrderOpenPrice(), sl, OrderTakeProfit(), 0))
                   Print("Не удалось изменить ордер ", OrderTicket());
             }
             if(ot==1) {
               if(opP_s==3) sl = NormalizeDouble(_trRv_H_LV1_0, Digits);
               if(opP_s==2) sl = NormalizeDouble(_trRv_L_LV1_0, Digits);
               if(opP_s==1) sl = NormalizeDouble(_trRv_L_LV2_0, Digits);

               if(OrderStopLoss()!=sl && MathAbs(sl-OrderOpenPrice())>MarketInfo(Symb, MODE_STOPLEVEL)*Point)
                 if(!OrderModify(OrderTicket(), OrderOpenPrice(), sl, OrderTakeProfit(), 0))
                   Print("Не удалось изменить ордер ", OrderTicket());
             }
           }
         }
       }
     }
     // открываем 
     if(HaveOpenPos()==false) {
       if(Close[1]>_trRv_H_LV1_1 && (Low[1] <=_trRv_H_LV1_1 || Low[2] <=_trRv_H_LV1_2) && Ask>_trRv_H_LV1_0) { // снизу вверх buy
         BuyPos(Lot_1, _trRv_L_LV1_0, _trRv_H_LV2_0, LEVEL2);
         BuyPos(Lot_2, _trRv_L_LV1_0, _trRv_H_LV3_0, LEVEL3);
         BuyPos(Lot_3, _trRv_L_LV1_0, _trRv_H_LV4_0, LEVEL4);
       } else 
       if(Close[1]<_trRv_L_LV1_1 && (High[1]>=_trRv_L_LV1_1 || High[2]>=_trRv_L_LV1_2) && Bid<_trRv_L_LV1_0) { // сверху вниз sell
         SellPos(Lot_1, _trRv_H_LV1_0, _trRv_L_LV2_0, LEVEL2);
         SellPos(Lot_2, _trRv_H_LV1_0, _trRv_L_LV3_0, LEVEL3);
         SellPos(Lot_3, _trRv_H_LV1_0, _trRv_L_LV4_0, LEVEL4);
       }
     }
   }
   timePrev = Time[1];
  }
//+------------------------------------------------------------------+
int AmountOpenPos(int ot=-1) {
  int i, k = OrdersTotal (), num=0;
  if(!(ot==0 || ot==1)) ot=-1;
  for (i=k-1; i>=0; i--) {
    if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==Symb && OrderMagicNumber()==MagicNumber) {
        if(ot==-1) {
          if (OrderType()==0 || OrderType()==1) num++;
        } else {
          if(ot==OrderType()) num++;
        }
      }
    }
  }
  return (num);
}
//+------------------------------------------------------------------+
bool HaveOpenPos(int ot=-1) {
  int i, k = OrdersTotal ();
  if(ot<0 || ot>1) ot=-1;
  for (i=k-1; i>=0; i--) {
    if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==Symb && OrderMagicNumber()==MagicNumber) {
        if(ot==-1) {
          if (OrderType()==0 || OrderType()==1) return (true);
        } else {
          if(ot==OrderType()) return (true);
        }
      }
    }
  }
  return (false);
}
//+------------------------------------------------------------------+
bool BuyPos(double _lot, double _sl=0, double _tp=0, string _comment=NULL) {
  RefreshRates();
  if (!OrderSend(Symb, OP_BUY, NormalizeDouble(_lot, 2), NormalizeDouble(Ask,Digits), Slippage, NormalizeDouble(_sl,Digits), NormalizeDouble(_tp,Digits), _comment, MagicNumber)) {
    Print("Не удалось OP_BUY!");
    return (false);
  }  
  return (true);
}
bool SellPos(double _lot, double _sl=0, double _tp=0, string _comment=NULL) {
  RefreshRates();
  if (!OrderSend(Symb, OP_SELL, NormalizeDouble(_lot, 2), NormalizeDouble(Bid,Digits), Slippage, NormalizeDouble(_sl,Digits), NormalizeDouble(_tp,Digits), _comment, MagicNumber)) {
    Print("Не удалось OP_SELL!");
    return (false); 
  }  
  return (true);
}
//+------------------------------------------------------------------+