Kudryashov

 
Уровень 8
Добро пожаловать в мой блог!

  Торгую в компаниях:


Группа "Стол заказов MQL"

Рейтинг 2146


_



UPDATE: Внимание! С ноября 2024 финансирование Стола заказов прекращено

Подробности здесь — zakaz.opentraders.ru/132091.html



Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 4000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от Kudryashov



Поздравляю!
2020-03-08 21:31:33Рейтинг 0

Проверка функции Комментариев 3
2016-12-03 16:28:58Рейтинг 0

Добавление оповещения к индикатору Комментариев 9
2017-11-03 10:44:40Рейтинг 0

Проверка функции

Доброе время суток!
Я не программист, а только учусь… Поэтому частенько ищу помощи *help* 
Если не в тему то удалите сообщение *spam* 
Суть «заказа» — проверить функцию. Так как приходиться частенько использовать 2 разные функции решил их объединить в одну.

1 Функция: расчет объема:
double LotsOptimized(string   symbol)
{
//--- Инициализация переменых ----------------------------------------
double   volume      = (double) Lots;
double   lot         = Lots;              //Значение первоначального лота
double   exponent    = LotExponent;       //Коэффицент умножения первоначального лота
double   count       = CountOpenOrders(symbol); //Количество открытых ордеров
int      digits      = (int)2;            //Количество символов лота после запятой
//--------------------------------------------------------------------
if (count > 0) volume = NormalizeDouble(lot * MathPow(exponent, count),digits);
//--------------------------------------------------------------------
return(volume);
}


2 функция: проверка корректности объема:
bool CheckVolumeValue(double volume)
{
string description;
double min_volume=SymbolInfoDouble(Symbol(),SYMBOL_VOLUME_MIN);   //Минимально допустимый объем для торговых операций
if(volume<min_volume)
   {
   description=StringFormat("Объем меньше минимально допустимого SYMBOL_VOLUME_MIN=%.2f",min_volume);
   return(FALSE);
   }
double max_volume=SymbolInfoDouble(Symbol(),SYMBOL_VOLUME_MAX);   //Максимально допустимый объем для торговых операций
if(volume>max_volume)
   {
   description=StringFormat("Объем больше максимально допустимого SYMBOL_VOLUME_MAX=%.2f",max_volume);
   return(FALSE);
   }
double volume_step=SymbolInfoDouble(Symbol(),SYMBOL_VOLUME_STEP); //Получим минимальную градацию объема
int ratio=(int)MathRound(volume/volume_step);
if(MathAbs(ratio*volume_step-volume)>0.0000001)
   {
   description=StringFormat("Объем не является кратным минимальной градации SYMBOL_VOLUME_STEP=%.2f, ближайший корректный объем %.2f",
                               volume_step,ratio*volume_step);
   return(FALSE);
   }
description="Корректное значение объема";
return(TRUE);
}


Пример использования выше перечисленных функций в коде:
...
      iLots = LotsOptimized(symbol);
      if (Signal(symbol) < 0 && CheckVolumeValue(iLots)==TRUE) ticket = OrderSend(symbol,OP_SELL,iLots,bid,3,0,0,"",MAGIC,0,Red);
...


Я решил объединить обе эти функции в одну, что бы она не только проверяла объем на корректность, но и выставляла корректные значения. в результате получилось это:
double LotsOptimized(string   symbol)
{
//--------------------------------------------------------------------
//string   symbol      = Symbol();
double   volume      = (double) Lots;
double   lot         = Lots;              //Значение первоначального лота
double   exponent    = LotExponent;       //Коэффицент умножения первоначального лота
double   count       = CountOpenOrders(); //Количество открытых ордеров
int      digits      = (int)2;            //Количество символов лота после запятой
//--------------------------------------------------------------------
string   description;
double   min_volume=SymbolInfoDouble(symbol,SYMBOL_VOLUME_MIN);   //Минимально допустимый объем для торговых операций
double   max_volume=SymbolInfoDouble(symbol,SYMBOL_VOLUME_MAX);   //Максимально допустимый объем для торговых операций
double   volume_step=SymbolInfoDouble(symbol,SYMBOL_VOLUME_STEP); //Получим минимальную градацию объема
int      ratio=(int)MathRound(volume/volume_step);
double   correct_volume;
//--------------------------------------------------------------------
if (count > 0) volume = NormalizeDouble(lot * MathPow(exponent, count),digits);
//--------------------------------------------------------------------
if(volume<min_volume)
   {
   description=StringFormat("Объем меньше минимально допустимого SYMBOL_VOLUME_MIN=%.2f",min_volume);
   return(min_volume);
   }
//--------------------------------------------------------------------
if(volume>max_volume)
   {
   description=StringFormat("Объем больше максимально допустимого SYMBOL_VOLUME_MAX=%.2f",max_volume);
   return(max_volume);
   }
//--------------------------------------------------------------------
if(MathAbs(ratio*volume_step-volume)>0.0000001)
   {
   description=StringFormat("Объем не является кратным минимальной градации SYMBOL_VOLUME_STEP=%.2f, ближайший корректный объем %.2f",
                               volume_step,ratio*volume_step);
   correct_volume = NormalizeDouble(ratio*volume_step,digits);
   return(correct_volume);
   }
//--------------------------------------------------------------------
description="Корректное значение объема";
return(volume);
}

Прошу проверить новоиспеченую функцию и указать на ошибки и/или исправить их.
Спасибо!
  • +2
  • Просмотров: 2558
  • 3 декабря 2016, 16:28
  • Kudryashov
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Советник WATR
Следующая запись в группе  
Доработка Bar Check-list
02 декабря 2016
03 декабря 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (3)

+
0
Вот уже готовый советник с моей функцией, там как раз 2 в одном.




//+------------------------------------------------------------------+
//|                                                      2Mashki.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern double Loss       = 3000;     // лось в рублях
extern double Profit     = 20;       // язь в рублях
extern int StopLoss      = 0;        // лось
extern int TakeProfit    = 0;        // язь
extern int TrailingStop  = 0;        // трал
extern int MA1Period     = 12;       // период МА1
extern int MA2Period     = 40;       // период МА2
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//| Установка ордера                                                 |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0,err=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)   sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)   sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Лот для усреднителя                                              |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   double MinimumLot = MarketInfo(NULL,MODE_MINLOT);
   double MaximumLot = MarketInfo(NULL,MODE_MAXLOT);

   if(CountTrades()>0) lot=NormalizeDouble(Lots*MathPow(KLot,CountTrades()),2);
   if(lot>MaxLot)lot=Lots;
   if(lot<MinimumLot) lot=MinimumLot;
   if(lot>MaximumLot) lot=MaximumLot;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenOrd()
  {
   double MA11=iMA(NULL,0,MA1Period,0,0,0,Shift);
   double MA12=iMA(NULL,0,MA1Period,0,0,0,Shift+1);
   double MA21=iMA(NULL,0,MA2Period,0,0,0,Shift);
   double MA22=iMA(NULL,0,MA2Period,0,0,0,Shift+1);

   if(MA11<MA21 && MA12>MA22)
     {
      PutOrder(1,Bid);
     }

   if(MA11>MA21 && MA12<MA22)
     {
      PutOrder(0,Ask);
     }
  }
//+------------------------------------------------------------------+
//| Простой трал                                                     |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() || OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Закрытие позиции по типу ордера                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      if(TrailingStop>0) Trailing();
      OpenOrd();
      if(AllProfit(0)>Profit) CloseAll(0);
      if(AllProfit(1)>Profit) CloseAll(1);
      if(AllProfit()>Profit || AllProfit()<-Loss) CloseAll();
      t=Time[0];
     }

   Comment("\n Открыто Buy ",CountOrders(0),
           "\n Открыто Sell ",CountOrders(1),
           "\n Общий профит: ",AllProfit(),
           "\n Профит по Buy: ",AllProfit(0),
           "\n Профит по Sell: ",AllProfit(1));
  }
//+------------------------------------------------------------------+

Редактирован: 4 декабря 2016, 11:18
avatar

  35  AM2 Сообщений: 16266 - Андрей

  • 4 декабря 2016, 09:16
+
0
:) 
avatar

  8  Kudryashov Автор Сообщений: 129

  • 4 декабря 2016, 12:44
  • ↑
+
0
Спасибо!
Ларчик оказывается просто открывался *good* 
avatar

  8  Kudryashov Автор Сообщений: 129

  • 7 декабря 2016, 18:45
  • ↑

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий