Группа "Стол заказов MQL"

Рейтинг 2073



РЕКОМЕНДУЮ



скальпинг м5 евро



1) свеча на м5 на 20 пипок что больше 14 пипок, торгуемся и открываем сделку селл на все депо, против тренда.
2) свеча на м5 20 пипок что больше 14, торгуемся открываем открываем сделку бай на все депо
3)свеча на м5 17 пипок что больше 14, но меньше предыдущей свечи, оставляем бай и доливаемся на все депо.
4) свеча на м5 15 пипок что больше 14 торгуемся и открываем селл на все депо.
5)свеча на м5 13 пипок что меньше 14 оставляем селл.
6) свеча на м5 14 что равно 14 оставляем селл.

представьте пожалуйста тест советника

пс ставьте плюсики у меня маленький эквити, потому за голос дадут 1-2 опыта
  • +10
  • Просмотров: 4899
  • 17 декабря 2016, 12:16
  • igrun
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
Следующая запись в группе  
Стрелка+алерт+уровни к индикатору OBV для МТ4
16 декабря 2016
18 декабря 2016

Комментарии (14)

+
+1
По одному заказу в месяц, в следующем напомните.
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 17 декабря 2016, 12:45
+
0
уверен что ами не заказывала в этом месяце советник, можно по ее ходатайству сделать советник быстрее?
avatar

  22  igrun Автор Сообщений: 1553 - igrun

  • 17 декабря 2016, 19:36
+
0
Если подпишется, то можно.
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 17 декабря 2016, 20:27
+
+1
Давай я подпишусь :) 
avatar

  17  vis Сообщений: 193 - ♫♪♫♪

  • 17 декабря 2016, 21:16
+
0
все готово *drinks* 
avatar

  22  igrun Автор Сообщений: 1553 - igrun

  • 17 декабря 2016, 21:22
+
0
После выходных буду смотреть.
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 17 декабря 2016, 21:41
+
0



нужно чтобы советник выбрал оптимальную цену, по видимому это процент от тренда, нужно чтобы открытые позиции ни как не влияли на переворот или доливку
Редактирован: 18 декабря 2016, 00:43
avatar

  22  igrun Автор Сообщений: 1553 - igrun

  • 17 декабря 2016, 23:54
+
0
А с кем торговаться-то? С ММ? Чтобы тренд развернул?
Редактирован: 18 декабря 2016, 07:26
avatar

  6  Glukozavr Сообщений: 76

  • 18 декабря 2016, 07:25
+
+2
Cделал то что смог разобрать из задания: zakaz.opentraders.ru/36552.html




//+------------------------------------------------------------------+
//|                                                        Igrun.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double Risk       = 10;       // риск
extern double Loss       = 3000;     // лось в рублях
extern double Profit     = 20;       // язь в рублях
extern int StopLoss      = 0;        // лось
extern int TakeProfit    = 0;        // язь
extern int Delta         = 90;       // размер свечи
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//| Установка ордера                                                 |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0,err=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)   sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)   sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Лот для усреднителя                                              |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   double MinimumLot = MarketInfo(NULL,MODE_MINLOT);
   double MaximumLot = MarketInfo(NULL,MODE_MAXLOT);

   if(Risk>0) lot=AccountEquity()*Risk/100000;// 10000*10/100000=1
   if(lot<MinimumLot) lot=MinimumLot;
   if(lot>MaximumLot) lot=MaximumLot;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenOrd()
  {
   double delta=Close[1]-Open[1];

   if(delta<0 && delta<-Delta*Point)
     {
      PutOrder(1,Bid);
     }

   if(delta>0 && delta>Delta*Point)
     {
      PutOrder(0,Ask);
     }
  }
//+------------------------------------------------------------------+
//| Закрытие позиции по типу ордера                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      OpenOrd();
      //if(AllProfit(0)>Profit) CloseAll(0);
      //if(AllProfit(1)>Profit) CloseAll(1);
      if(AllProfit()>Profit || AllProfit()<-Loss) CloseAll();
      t=Time[0];
     }

   Comment("\n Открыто Buy ",CountOrders(0),
           "\n Открыто Sell ",CountOrders(1),
           "\n Общий профит: ",AllProfit(),
           "\n Профит по Buy: ",AllProfit(0),
           "\n Профит по Sell: ",AllProfit(1));
  }
//+------------------------------------------------------------------+


Редактирован: 24 декабря 2016, 07:31
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 18 декабря 2016, 08:38
+
0
можешь из этого мне советника собрать для мт4?
avatar

  22  igrun Автор Сообщений: 1553 - igrun

  • 18 декабря 2016, 14:02
+
0
Это и есть советник.
См. Как добавлять советники, индикаторы и скрипты в MetaTrader
(раздел «ДОБАВЛЕНИЕ СОВЕТНИКА В ВИДЕ КОДА»)
avatar

  45  Bishop Сообщений: 5709 - АЛЬФАХАМЕЦ-Машковод

  • 18 декабря 2016, 14:12
+
0
Вот файлик: www.opentraders.ru/downloads/1428/
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 18 декабря 2016, 14:24
+
0
объясни по простому как настроить это чудо советник у меня на тесте ноль сделок
extern double Lots = 0.1; // лот
extern double Risk = 10; // риск
extern double Loss = 3000; // лось в рублях
extern double Profit = 20; // язь в рублях
extern int StopLoss = 0; // лось
extern int TakeProfit = 0; // язь
extern int Delta = 90; // размер свечи
extern int Slip = 30; // реквот
extern int Magic = 123; // магик
чтой то?
avatar

  22  igrun Автор Сообщений: 1553 - igrun

  • 18 декабря 2016, 15:09
+
+1
скрины логи скидывай сюда
avatar

  34  AM2 Сообщений: 15826 - Андрей

  • 18 декабря 2016, 15:53

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари