Happytigra

 
Уровень 6
Добро пожаловать в мой блог!

  Торгую в компаниях:


Группа "Стол заказов MQL"

Рейтинг 2081


Если Вы хотите заказать советник или индикатор, то публикуйте в эту группу тех. задание. Если Ваш заказ не очень сложный, то велика вероятность, что Вам его смогут сделать даже бесплатно



Программистам MQL: подпишитесь на группу, чтобы получать уведомления о заказах.

Не забывайте указывать платформу: MT4 или MT5



Свыше 1000 заказов уже выполнено бесплатно!





Перед заказом прочитайте Правила работы Стола заказов



СДЕЛАТЬ ЗАКАЗ →

* нужно быть зарегистрированным на сайте для создания заказа

** уровень должен быть 3 или выше, чтобы заказ был рассмотрен штатным программистом Стола (см. правила)


РЕКОМЕНДУЮ



*Реклама от создателя группы

Лучшее от Happytigra



Написать советник на основе индикатора
2018-04-30 11:55:48Рейтинг 0

Советник на Zigzag и Stohastic Комментариев 5
2017-01-03 17:34:21Рейтинг 0

Советник по AO+AC+SAR Комментариев 12
2015-04-17 02:31:18Рейтинг 0

Советник на индикаторе АО Комментариев 13
2016-09-29 22:19:20Рейтинг 0

Доработка советника ZigZagFractal Комментариев 20
2015-03-29 13:13:39Рейтинг 0

Советник на Zigzag и Stohastic

Добрый день
Прошу написать советник на индикаторах ZigZag и Stoсhastic

Открытие ордера Sell
Stoсhastic Oscillator пересекает линию 80% сверху вниз
SL на уровне предыдущего максимума ZigZag + 5 пунктов (кол-во можно менять в настройках), TP = 2 SL, а также можно устанавливать в пунктах SL и TP.

Открытие ордера Buy
Stoсhastic Oscillator пересекает линию 20% снизу вверх
SL на уровне предыдущего минимума ZigZag (кол-во можно менять в настройках), TP = 2 SL, а также можно устанавливать в пунктах SL и TP.

В настройках:
параметры ZigZag, Stohastic, количесво пуктов плюс к SL от макс/мин зигзага, кол-во пунктов для SL и TP, переключатель SL и TP по индикатору или в пунктах, открывать сделку при каждом сигнале или только один открытый ордер Да/Нет.

Заранее спасибо.
  • +2
  • Просмотров: 2646
  • 3 января 2017, 17:34
  • Happytigra
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Стол заказов MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
  Предыдущая запись в группе
Прошу написать советник для MT4 по индикатору
Следующая запись в группе  
Доработка
03 января 2017
03 января 2017

Комментарии (5)

+
0
Завтра буду смотреть.
avatar

  34  AM2 Сообщений: 15869 - Андрей

  • 3 января 2017, 20:17
+
0
Я начал делать, покажите на скрине куда ставить стопы, на какой излом?




//+------------------------------------------------------------------+
//|                                                        Happy.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict
//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int Slip          = 30;       // реквот
extern int StLevel       = 20;       // уровень индикатора
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

extern int InpDepth      = 12;
extern int InpDeviation  = 5;
extern int InpBackstep   = 3;

input int InpKPeriod     = 5; // K Period
input int InpDPeriod     = 3; // D Period
input int InpSlowing     = 3; // Slowing
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits); else sl=GetZZPrice(0);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);else sl=GetZZPrice(0);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double st1=iStochastic(NULL,0,InpKPeriod,InpDPeriod,InpSlowing,0,0,0,Shift);
   double st2=iStochastic(NULL,0,InpKPeriod,InpDPeriod,InpSlowing,0,0,0,Shift+1);

   if(st1>StLevel && st2<StLevel)
     {
      PutOrder(0,Ask);
     }

   if(st1<100-StLevel && st2>100-StLevel)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double GetZZPrice(int ne=0)
  {
   double zz;
   int    i,k=iBars(NULL,0),ke=0;

   for(i=1; i<k; i++)
     {
      zz=iCustom(NULL,0,"ZigZag",InpDepth,InpDeviation,InpBackstep,0,i);
      if(zz!=0)
        {
         ke++;
         if(ke>ne) return(zz);
        }
     }
   Print("GetExtremumZZPrice(): Экстремум ЗигЗага номер ",ne," не найден");
   return(0);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1)
     {
      OpenPos();
     }
  }
//+------------------------------------------------------------------+

Редактирован: 5 января 2017, 16:10
avatar

  34  AM2 Сообщений: 15869 - Андрей

  • 4 января 2017, 21:46
+
0
На рисунке отметила
avatar

  6  Happytigra Автор Сообщений: 138

  • 4 января 2017, 22:04
+
0
Вот так примерно:




//+------------------------------------------------------------------+
//|                                                        Happy.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict
//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int Delta         = 100;      // плюс к стопу
extern int Slip          = 30;       // реквот
extern int StLevel       = 20;       // уровень индикатора
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Many          = 0;        // 1-много ордеров
extern int Magic         = 123;      // магик

extern int InpDepth      = 12;
extern int InpDeviation  = 5;
extern int InpBackstep   = 3;

input int InpKPeriod     = 5; // K Period
input int InpDPeriod     = 3; // D Period
input int InpSlowing     = 3; // Slowing

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits); else sl=GetZZPrice(0)+Delta*Point;
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);else sl=GetZZPrice(0)-Delta*Point;
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double st1=iStochastic(NULL,0,InpKPeriod,InpDPeriod,InpSlowing,0,0,0,Shift);
   double st2=iStochastic(NULL,0,InpKPeriod,InpDPeriod,InpSlowing,0,0,0,Shift+1);

   if(st1>StLevel && st2<StLevel)
     {
      PutOrder(0,Ask);
     }

   if(st1<100-StLevel && st2>100-StLevel)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double GetZZPrice(int ne=0)
  {
   double zz;
   int    i,k=iBars(NULL,0),ke=0;

   for(i=1; i<k; i++)
     {
      zz=iCustom(NULL,0,"ZigZag",InpDepth,InpDeviation,InpBackstep,0,i);
      if(zz!=0)
        {
         ke++;
         if(ke>ne) return(zz);
        }
     }
   Print("GetExtremumZZPrice(): Экстремум ЗигЗага номер ",ne," не найден");
   return(0);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1 && Many==0)
     {
      OpenPos();
     }

   if(t!=Time[0] && Many==1)
     {
      OpenPos();
      t=Time[0]; 
     }
  }
//+------------------------------------------------------------------+
avatar

  34  AM2 Сообщений: 15869 - Андрей

  • 5 января 2017, 16:20
+
0
Спасибо!
avatar

  6  Happytigra Автор Сообщений: 138

  • 5 января 2017, 17:17

Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий
Начать торговлю с Альпари